INFO. RELASJONER

Gjelder for: beregnet kolonne beregnet tabell mål visualobjektberegning DAX spørring

Returnerer en tabell med informasjon om hver relasjon i den semantiske modellen. Denne funksjonen inneholder metadata om relasjoner mellom tabeller.

Syntaks

INFO.RELATIONSHIPS ( [<Restriction name>, <Restriction value>], ... )

Parametere

Parametere er valgfrie for denne DAX-funksjonen. Når parametere brukes, må begge angis. Mer enn ett par parametere er tillatt. Begrensningsnavnet og -verdien er tekst og skrives inn i doble anførselstegn.

Begrensninger

Vanligvis kan alle kolonnene i DAX funksjonsresultatene brukes som en begrensning. Tilleggsbegrensninger kan også være tillatt.

Returverdi

En tabell med kolonner som samsvarer med skjemaradsettet for relasjoner i den gjeldende semantiske modellen.

Merknader

• Brukes vanligvis i DAX spørringer til å undersøke og dokumentere metadata for modell.
• Nødvendige tillatelser avhenger av verten. Spørring av fullstendige metadata kan kreve modelladministratortillatelser.

Eksempel

Følgende DAX spørring kan kjøres i DAX spørringsvisning:

EVALUATE
	INFO.RELATIONSHIPS()

Eksempel 2 – DAX spørring med koblinger

Følgende DAX spørring kan kjøres i DAX spørringsvisning:

EVALUATE
VAR _Relationships = 
    SELECTCOLUMNS(
        INFO.RELATIONSHIPS(),
        "Relationship Name", [Name],
        "Is Active", [IsActive],
        "Type", [Type],
        "Cross Filtering", [CrossFilteringBehavior],
        "From Table ID", [FromTableID],
        "From Column ID", [FromColumnID],
        "To Table ID", [ToTableID],
        "To Column ID", [ToColumnID]
    )

VAR _FromTables = 
    SELECTCOLUMNS(
        INFO.TABLES(),
        "FromTableID", [ID],
        "From Table Name", [Name]
    )

VAR _ToTables = 
    SELECTCOLUMNS(
        INFO.TABLES(),
        "ToTableID", [ID],
        "To Table Name", [Name]
    )

VAR _FromColumns = 
    SELECTCOLUMNS(
        INFO.COLUMNS(),
        "FromColumnID", [ID],
        "From Column Name", [Name]
    )

VAR _ToColumns = 
    SELECTCOLUMNS(
        INFO.COLUMNS(),
        "ToColumnID", [ID],
        "To Column Name", [Name]
    )

VAR _CombinedTable1 = 
    NATURALLEFTOUTERJOIN(
        _Relationships,
        _FromTables
    )

VAR _CombinedTable2 = 
    NATURALLEFTOUTERJOIN(
        _CombinedTable1,
        _ToTables
    )

VAR _CombinedTable3 = 
    NATURALLEFTOUTERJOIN(
        _CombinedTable2,
        _FromColumns
    )

VAR _CombinedTable4 = 
    NATURALLEFTOUTERJOIN(
        _CombinedTable3,
        _ToColumns
    )

RETURN
    SELECTCOLUMNS(
        _CombinedTable4,
        "Relationship Name", [Relationship Name],
        "From Table", [From Table Name],
        "From Column", [From Column Name],
        "To Table", [To Table Name],
        "To Column", [To Column Name],
        "Is Active", [Is Active],
        "Type", [Type],
        "Cross Filtering", [Cross Filtering]
    )
ORDER BY [Relationship Name]

Se også

• INFO. TABELLER
• INFO. KOLONNER
• INFO. PARTISJONER
• Oversikt over infofunksjoner