Condividi tramite

INFORMAZIONI. RELAZIONI

Si applica a: colonna Calcolata tabella calcolata query di calcolo visivo DAX

Restituisce una tabella con informazioni su ogni relazione nel modello semantico. Questa funzione fornisce metadati sulle relazioni tra tabelle.

Sintassi

INFO.RELATIONSHIPS ( [<Restriction name>, <Restriction value>], ... )

Parametri

I parametri sono facoltativi per questa funzione DAX. Quando si usano parametri, è necessario specificare entrambi. Sono consentiti più di una coppia di parametri. Il nome e il valore della restrizione sono testo e immessi tra virgolette doppie.

Termine Definition
Nome restrizione Nome della restrizione utilizzata per filtrare i risultati.
Valore della restrizione Valore utilizzato per filtrare i risultati della restrizione.

Restrictions

In genere, tutte le colonne dei risultati della funzione DAX possono essere usate come restrizione. Possono essere consentite anche restrizioni aggiuntive.

Valore restituito

Tabella le cui colonne corrispondono al set di righe dello schema per le relazioni nel modello semantico corrente.

colonna Description
Documento d'identità Identificatore univoco per la relazione
ModelID Chiave esterna al modello contenente questa relazione
Nome Nome della relazione
IsActive Valore booleano che indica se la relazione è attiva
TIPO Tipo di relazione (ad esempio, OneToMany, ManyToOne)
Comportamento di Filtraggio Incrociato Comportamento di filtro incrociato (ad esempio OneDirection, BothDirections)
JoinOnDateBehavior Comportamento per i join basati su data
AffidarsiAll'IntegritàReferenziale Valore booleano che indica se basarsi sull'integrità referenziale
FromTableID Chiave esterna alla tabella di origine nella relazione
FromColumnID Chiave esterna alla colonna di origine nella relazione
FromCardinality Cardinalità sul lato "from" della relazione
ToTableID Chiave esterna alla tabella di destinazione nella relazione
ToColumnID Chiave esterna alla colonna di destinazione nella relazione
ToCardinality Cardinalità sul lato "a" della relazione
stato Stato corrente della relazione
RelationshipStorageID Chiave esterna alle informazioni di archiviazione delle relazioni
RelationshipStorage2ID Informazioni sull'archiviazione delle relazioni esterne con la chiave secondaria
ModifiedTime Data e ora dell'ultima modifica della relazione
RefreshedTime Data e ora dell'ultimo aggiornamento della relazione
Comportamento di Filtraggio della Sicurezza Comportamento di filtro della sicurezza per la relazione

Osservazioni:

  • In genere usato nelle DAX query per esaminare e documentare i metadati del modello.
  • Le autorizzazioni necessarie dipendono dall'host. L'esecuzione di query su metadati completi può richiedere autorizzazioni di amministratore del modello.

Example

La query di DAX seguente può essere eseguita in DAX vista query:

EVALUATE
	INFO.RELATIONSHIPS()

Esempio 2: DAX query con join

La query di DAX seguente può essere eseguita in DAX vista query:

EVALUATE
VAR _Relationships = 
    SELECTCOLUMNS(
        INFO.RELATIONSHIPS(),
        "Relationship Name", [Name],
        "Is Active", [IsActive],
        "Type", [Type],
        "Cross Filtering", [CrossFilteringBehavior],
        "From Table ID", [FromTableID],
        "From Column ID", [FromColumnID],
        "To Table ID", [ToTableID],
        "To Column ID", [ToColumnID]
    )

VAR _FromTables = 
    SELECTCOLUMNS(
        INFO.TABLES(),
        "FromTableID", [ID],
        "From Table Name", [Name]
    )

VAR _ToTables = 
    SELECTCOLUMNS(
        INFO.TABLES(),
        "ToTableID", [ID],
        "To Table Name", [Name]
    )

VAR _FromColumns = 
    SELECTCOLUMNS(
        INFO.COLUMNS(),
        "FromColumnID", [ID],
        "From Column Name", [Name]
    )

VAR _ToColumns = 
    SELECTCOLUMNS(
        INFO.COLUMNS(),
        "ToColumnID", [ID],
        "To Column Name", [Name]
    )

VAR _CombinedTable1 = 
    NATURALLEFTOUTERJOIN(
        _Relationships,
        _FromTables
    )

VAR _CombinedTable2 = 
    NATURALLEFTOUTERJOIN(
        _CombinedTable1,
        _ToTables
    )

VAR _CombinedTable3 = 
    NATURALLEFTOUTERJOIN(
        _CombinedTable2,
        _FromColumns
    )

VAR _CombinedTable4 = 
    NATURALLEFTOUTERJOIN(
        _CombinedTable3,
        _ToColumns
    )

RETURN
    SELECTCOLUMNS(
        _CombinedTable4,
        "Relationship Name", [Relationship Name],
        "From Table", [From Table Name],
        "From Column", [From Column Name],
        "To Table", [To Table Name],
        "To Column", [To Column Name],
        "Is Active", [Is Active],
        "Type", [Type],
        "Cross Filtering", [Cross Filtering]
    )
ORDER BY [Relationship Name]

Vedere anche

  • Last updated on