Erstellen eines Satzes von Tabellennavigationsschaltflächen

Ein allgemeines Merkmal vieler Anwendungen ist eine Reihe von Navigationsschaltflächen, die es den Benutzern ermöglicht, sich in der Tabelle zu bewegen. Dazu gehören gewöhnlich Schaltflächen, über die der Datensatzzeiger zum nächsten oder vorhergehenden bzw. zum ersten oder letzten Datensatz innerhalb der Tabelle bewegt wird.

Entwerfen von Navigationsschaltflächen

Jede dieser Schaltflächen benötigt einige Merkmale und Funktionen, die sie mit den anderen gemeinsam hat, daher ist es sinnvoll, eine Navigationsschaltflächen-Klasse zu erstellen. Die einzelnen Schaltflächen können die hier festgelegte allgemeine Darstellung und die Funktionalität dann einfach erben. Die übergeordnete Klasse ist die Navbutton-Klasse, die weiter unten in diesem Abschnitt definiert wird.

Nachdem die übergeordnete Klasse definiert wurde, werden mit den folgenden Unterklassen die Funktionalität und die Darstellung für jede der vier Navigationsschaltflächen speziell festgelegt: navTop, navPrior, navNext, navBottom.

Zum Schluss wird eine Containerklasse, vcr, erstellt, zu der die einzelnen Navigationsschaltflächen hinzugefügt werden. Der Container wiederum kann zu einem Formular oder zu einer Symbolleiste hinzugefügt werden, um die Tabellennavigation verfügbar zu machen.

Definition der NAVBUTTON-Klasse

Um Navbutton zu erstellen, speichern Sie die folgenden sechs Klassendefinitionen (Navbutton, navTop, navBottom, navPrior, navNext und vcr) in einer Programmdatei wie z. B. Navclass.prg ab.

Definition der generischen Navigationsschaltflächen-Klasse

DEFINE CLASS Navbutton AS
COMMANDBUTTON
  Height = 25
  Width = 25
  TableAlias = ""

PROCEDURE Click
  IF NOT EMPTY(This.TableAlias)
   SELECT (This.TableAlias)
  ENDIF
ENDPROC

PROCEDURE RefreshForm
  _SCREEN.ActiveForm.Refresh
ENDPROC

ENDDEFINE

Die speziellen Navigationsschaltflächen basieren alle auf der Navbutton-Klasse. Über den folgenden Code wird die Schaltfläche Anfang für den Navigationsschaltflächen-Satz definiert. Die verbleibenden drei Navigationsschaltflächen werden in der folgenden Tabelle definiert. Die vier Klassendefinitionen ähneln einander, so dass nur die erste Definition ausführlich kommentiert ist.

Definition der Navigationsschaltfläche "Anfang"

DEFINE CLASS navTop AS Navbutton
  Caption = "|<"

PROCEDURE Click

  DODEFAULT( )
  GO TOP
  THIS.RefreshForm

ENDPROC

ENDDEFINE

Die anderen Navigationsschaltflächen haben ähnliche Klassendefinitionen.

Definition der anderen Navigationsschaltflächen-Klassen

DEFINE CLASS navNext AS Navbutton
  Caption = ">"

PROCEDURE Click
  DODEFAULT( )
  SKIP 1
  IF EOF( )
   GO BOTTOM
  ENDIF
  THIS.RefreshForm
ENDPROC
ENDDEFINE

DEFINE CLASS navPrior AS Navbutton
  Caption = "<"

PROCEDURE Click
  DODEFAULT( )
  SKIP –1
  IF BOF( )
   GO TOP
  ENDIF
  THIS.RefreshForm
ENDPROC
ENDDEFINE

DEFINE CLASS navBottom AS
Navbutton
  Caption = ">|"

PROCEDURE Click
  DODEFAULT( )
  GO BOTTOM
  THIS.RefreshForm
ENDPROC
ENDDEFINE

Die folgende Klassendefinition enthält alle vier Navigationsschaltflächen, so dass sie als Einheit zu einem Formular hinzugefügt werden können. Die Klasse enthält ebenfalls eine Methode, über die die TableAlias-Eigenschaft für die Schaltflächen festgelegt werden kann.

Definition der Tabellennavigations-Steuerelementklasse

DEFINE CLASS vcr AS CONTAINER
   Height = 25
   Width = 100
   Left = 3
   Top = 3

   ADD OBJECT cmdTop AS navTop ;
      WITH Left = 0
   ADD OBJECT cmdPrior AS navPrior ;
      WITH Left = 25
   ADD OBJECT cmdNext AS navNext ;
      WITH Left = 50
   ADD OBJECT cmdBot AS navBottom ;
      WITH Left = 75

PROCEDURE SetTable(cTableAlias)
   IF TYPE("cTableAlias") = 'C'
      THIS.cmdTop.TableAlias = ;
         cTableAlias
      THIS.cmdPrior.TableAlias = ;
         cTableAlias
      THIS.cmdNext.TableAlias = ;
         cTableAlias
      THIS.cmdBot.TableAlias = ;
         cTableAlias
   ENDIF
ENDPROC

ENDDEFINE

Nachdem Sie die Klasse definiert haben, können Sie Unterklassen aus dieser ableiten oder sie zu einem Formular hinzufügen.

Erstellen einer Unterklasse, die auf der neuen Klasse basiert

Sie können auch Unterklassen basierend auf vcr mit zusätzlichen Schaltflächen wie Suchen, Bearbeiten, Speichern und Beenden erstellen. Die Unterklasse vcr2 hat z. B. die Schaltfläche Quit (Beenden).

Definition einer Unterklasse für ein Tabellennavigations-Steuerelement

DEFINE CLASS vcr2 AS vcr
ADD OBJECT cmdQuit AS
COMMANDBUTTON WITH ;
   Caption = "Quit",;
   Height = 25, ;
   Width = 50
Width = THIS.Width + THIS.cmdQuit.Width
cmdQuit.Left = THIS.Width - ; 
   THIS.cmdQuit.Width

PROCEDURE cmdQuit.CLICK
   RELEASE THISFORM
ENDPROC

ENDDEFINE

Vcr2 verfügt über die gleichen Eigenschaften und die gleiche Funktionalität wie vcr und zusätzlich über eine neue Befehlsschaltfläche. Zudem muss der bestehende Code nicht erneut geschrieben werden.

In der Unterklasse widergespiegelte Änderungen zu VCR

Aufgrund der Vererbung werden Änderungen an der übergeordneten Klasse in allen entsprechenden Unterklassen widergespiegelt. Sie könnten dem Benutzer beispielsweise mitteilen, dass das Ende der Tabelle erreicht wurde. Dabei brauchen Sie lediglich die IF EOF( )-Anweisung in navNext.Click folgendermaßen zu ändern:

IF EOF( )
   GO BOTTOM
   SET MESSAGE TO "Bottom of the table"
ELSE
   SET MESSAGE TO
ENDIF

Ebenfalls könnten Sie den Benutzer informieren, dass der Beginn der Tabelle erreicht wurde. Dabei müssen Sie lediglich die IF BOF( )-Anweisung in navPrior.Click folgendermaßen ändern:

IF BOF()
   GO TOP
   SET MESSAGE TO "Top of the table"
ELSE
   SET MESSAGE TO
ENDIF

Wurden diese Änderungen in den Klassen navNext und navPrior eingearbeitet, dann wirken sie sich automatisch auf die entsprechenden Schaltflächen in vcr und vcr2 aus.

Hinzufügen von VCR zu einer Formularklasse

Nachdem vcr als Steuerelement definiert wurde, kann das Steuerelement in die Definition eines Containers eingefügt werden. Der folgende zu Navclass.prg hinzugefügte Code definiert z. B. ein Formular mit zusätzlichen Navigationsschaltflächen:

DEFINE CLASS NavForm AS Form
   ADD OBJECT oVCR AS vcr
ENDDEFINE

Ausführen des Formulars, in dem VCR enthalten ist

Nachdem die Formularunterklasse definiert wurde, ist es sehr leicht für Sie, diese mit Hilfe der entsprechenden Befehle anzuzeigen.

So zeigen Sie das Formular an

1. Laden Sie die Klassendefinition:

   SET PROCEDURE TO navclass ADDITIVE
   

2. Erstellen Sie ein Objekt, das auf der navform-Klasse basiert:

   frmTest = CREATEOBJECT("navform")
   

3. Rufen Sie die Show-Methode des Formulars auf:

   frmTest.Show
   

Wenn Sie die SetTable-Methode von oVCR (das VCR-Objekt in NavForm) nicht aufrufen, dann wird, wenn der Benutzer auf die Navigationsschaltflächen klickt, der Datensatzzeiger der Tabelle im aktuellen Arbeitsbereich verschoben. Sie können über die SetTable-Methode angeben, in welcher Tabelle der Datensatzzeiger verschoben werden soll.

frmTest.oVCR.SetTable("customer")

Anmerkung   Wenn der Benutzer das Formular schließt, wird frmTest auf einen NULL-Wert (.NULL.) gesetzt. Mit Hilfe des Befehls RELEASE können Sie die Objektvariable aus dem Arbeitsspeicher entfernen. In Programmdateien erstellte Objektvariablen werden aus dem Arbeitsspeicher entfernt, wenn das Programm beendet wird.

Siehe auch

Programmgesteuertes Schreiben von Klassendefinitionen | Richtlinien für Methoden- und Ereigniscode | Definition eines Datenraster-Steuerelements | Caption-Eigenschaft | Height | SetAll | Objektorientierte Programmierung