SetAll-Methode

Weist eine Eigenschaftseinstellung allen Klassen oder einer bestimmten Klasse von Steuerelementen in einem Container-Objekt zu.

Container.SetAll(cProperty, Value [, cClass])

Parameter

  • cProperty
    Gibt die zu setzende Eigenschaft an.
  • Value
    Gibt die neue Einstellung der Eigenschaft an. Der Datentyp von Value ist abhängig von der gesetzten Eigenschaft.
  • cClass
    Gibt den Namen der Klasse an, auf der das Objekt basiert, nicht die Visual FoxPro-Basisklasse des Objekts.

Hinweise

Verwenden Sie die SetAll-Methode, um für alle Klassen oder eine bestimmte Klasse von Steuerelementen in einem Container-Objekt eine Eigenschaft zu setzen. Um beispielsweise für alle Spaltenobjekte eines Datenraster-Steuerelements (Grid) die BackColor-Eigenschaft auf "Rot" zu setzen, geben Sie Folgendes ein:

Form1.Grid1.SetAll("BackColor", RGB(255, 0, 0), "Column")

Sie können die Eigenschaften auch für Objekte setzen, die den Inhalt anderer Objekte innerhalb des Containers darstellen. Um die ForeColor-Eigenschaft der Kopfbereiche in den einzelnen Spaltenobjekten eines Datenraster-Steuerelements (Grid) auf "Grün" zu setzen, geben Sie Folgendes ein:

Form1.Grid1.SetAll("ForeColor", RGB(0, 255, 0), "Header")

Beispiel

Das folgende Beispiel verwendet die SetAll-Methode mit der DynamicBackColor-Eigenschaft, um die Hintergrundfarben für die Datensätze in einem Datenraster-Steuerelement (Grid) anzugeben. Ist die Nummer eines im Datenraster angezeigten Datensatzes gerade, hat die DynamicBackColor-Eigenschaft des Datensatzes den Wert "weiß"; andernfalls hat sie den Wert "grün".

Ein Datenraster-Steuerelement (Grid) wird auf dem Formular positioniert; die Tabelle customer wird geöffnet, und ihr Inhalt wird im Datenraster angezeigt. Mit der Caption-Eigenschaft wird eine andere Spaltenkopfbeschriftung ("Customer ID") für das Feld CUST_ID angegeben. Zum Schließen des Formulars wird eine Befehlsschaltfläche auf dem Formular positioniert.

CLOSE ALL  && Close tables and databases
OPEN DATABASE (HOME(2) + 'Data\testdata')

USE customer  IN 0  && Opens Customer table

frmMyForm = CREATEOBJECT('Form')  && Create a form
frmMyForm.Closable = .f.  && Disable the window pop-up menu

frmMyForm.AddObject('cmdCommand1','cmdMyCmdBtn')  && Add Command button
frmMyForm.AddObject('grdGrid1','Grid')  && Add Grid control

frmMyForm.grdGrid1.Left = 25  && Adjust Grid position

frmMyForm.grdGrid1.SetAll("DynamicBackColor", "IIF(MOD(RECNO( ), 2)=0, RGB(255,255,255), RGB(0,255,0))", "Column")  && Alternate white and green records

frmMyForm.grdGrid1.Visible = .T.  && Grid control visible
frmMyForm.cmdCommand1.Visible =.T.  && "Quit" Command button visible
frmMyForm.grdGrid1.Column1.Header1.Caption = 'Customer ID'

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS cmdMyCmdBtn AS CommandButton  && Create Command button
   Caption = '\<Quit'  && Caption on the Command button
   Cancel = .T.  && Default Cancel Command button (Esc)
   Left = 125  && Command button column
   Top = 210  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      CLEAR EVENTS  && Stop event processing, close form
      CLOSE ALL  && Close table and database
ENDDEFINE

Siehe auch

SaveAs-Methode | SaveAsClass-Methode

Betrifft: Column-Objekt | Schaltflächengruppe-Steuerelement (CommandGroup) | Container-Objekt | Formularobjekt (Form) | Formularsatz-Objekt (FormSet) | Datenraster-Steuerelement (Grid) | Optionsgruppen-Steuerelement (OptionGroup) | Seitenobjekt (Page) | Seitenrahmen-Steuerelement (PageFrame) | _SCREEN | Symbolleisten-Objekt

  • Last updated on