Snabbstart: Distribuera ett Azure DocumentDB-kluster med Bicep

I den här snabbstarten distribuerar du ett nytt Azure DocumentDB-kluster med Bicep. Den här snabbstarten innehåller stegvisa instruktioner som hjälper dig att komma igång snabbt. Det här klustret innehåller alla dina MongoDB-resurser: databaser, samlingar och dokument. Den ger en unik slutpunkt för verktyg och programutvecklingspaket (SDK:er) för att ansluta till Azure DocumentDB och utföra åtgärder.

Prerequisites

  • En prenumeration på Azure

Konfigurera miljö

Konfigurera Din Azure CLI-miljö för att hantera Azure DocumentDB-resurser i din prenumeration.

  1. Börja i en tom katalog.

  2. Logga in på Azure CLI.

    az login

  3. Kontrollera målprenumerationen för Azure.

    az account show

    Anmärkning

    Om du inte är ansluten till den prenumeration du förväntade dig använder du det här kommandot för att ändra din prenumeration:

    az account set --subscription "<subscription-name>"

    Mer information finns i Hantera Azure-prenumerationer med Azure CLI.

Förbereda Bicep-mallen

Skapa och konfigurera en Bicep-fil för att definiera de resurser som krävs för att distribuera ett Azure DocumentDB-kluster.

  1. Skapa en ny main.bicep-fil i projektkatalogen.

  2. Lägg till den här mallen i filens innehåll.

    @description('Cluster name')
@minLength(8)
@maxLength(40)
param clusterName string = 'msdocs-${uniqueString(resourceGroup().id)}'

@description('Location for the cluster.')
param location string = resourceGroup().location

@description('Username for admin user')
param adminUsername string

@secure()
@description('Password for admin user')
@minLength(8)
@maxLength(128)
param adminPassword string

resource cluster 'Microsoft.DocumentDB/mongoClusters@2025-09-01' = {
  name: clusterName
  location: location
  properties: {
    administrator: {
      userName: adminUsername
      password: adminPassword
    }
    serverVersion: '8.0'
    sharding: {
      shardCount: 1
    }
    storage: {
      sizeGb: 32
    }
    highAvailability: {
      targetMode: 'Disabled'
    }
    compute: {
      tier: 'M10'
    }
  }
}

resource firewallRules 'Microsoft.DocumentDB/mongoClusters/firewallRules@2025-09-01' = {
  parent: cluster
  name: 'AllowAllAzureServices'
  properties: {
    startIpAddress: '0.0.0.0'
    endIpAddress: '0.0.0.0'
  }
}

    Tips/Råd

    Mer information om alternativ med hjälp av resursen finns i Microsoft.DocumentDB/mongoclustersMicrosoft.DocumentDB/mongoclusters.

Använd mallen

Distribuera mallen som skapades i föregående steg med hjälp av en Azure Resource Manager-distribution.

  1. az group create Använd kommandot för att skapa en ny resursgrupp i din prenumeration.

    az group create \
    --name "<resource-group-name>" \
    --location "<location>"

  2. Använd az deployment group create för att tillämpa bicep-mallen. Du uppmanas sedan att ange ett värde för parametrarna adminUsername och adminPassword .

    az deployment group create \
    --resource-group "<resource-group-name>" \
    --template-file 'main.bicep'

    Tips/Råd

    Du kan också använda alternativet --parameters för att skicka in en parameterfil med fördefinierade värden.

    az deployment group create \
    --resource-group "<resource-group-name>" \
    --template-file 'main.bicep' \
    --parameters @main.parameters.json

    I det här exemplet innehåller JSON-filen clusteradmin och P@ssw.rd värden för parametrarna adminUsername respektive adminPassword.

    {
  "$schema": "https://schema.management.azure.com/schemas/2015-01-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "adminUsername": {
      "value": "clusteradmin"
    },
    "adminPassword": {
      "value": "P@ssw.rd"
    }
  }
}

  3. Vänta tills distributionsåtgärden har slutförts innan du går vidare.

Granska distribuerade resurser

Visa en lista över De Azure DocumentDB-resurser som har distribuerats till resursgruppen.

  1. Använd az resource list för att hämta en lista över resurser i resursgruppen.

    az resource list \
    --resource-group "<resource-group-name>" \
    --namespace "Microsoft.DocumentDB" \
    --resource-type "mongoClusters" \
    --query "[].name" \
    --output json

  2. I exempelutdata letar du efter resurser som har en typ av Microsoft.DocumentDB/mongoClusters. Här är ett exempel på vilken typ av utdata du kan förvänta dig:

    [
  "msdocs-documentdb-example-cluster"
]

Rensa resurser

När du är klar med ditt Azure DocumentDB-kluster kan du ta bort de Azure-resurser som du skapade så att du inte debiteras fler avgifter.

  1. Använd az group delete för att ta bort resursgruppen från din prenumeration.

    az group delete \
    --name "<resource-group-name>" \
    --yes \
    --no-wait

    Important

    Se till att du inte längre behöver resurserna innan du kör det här kommandot eftersom de tas bort permanent.

Relaterat innehåll

  • Last updated on