Partilhar via

Como agrupar arquivos por extensão (LINQ) (Visual Basic)

Este exemplo mostra como o LINQ pode ser usado para executar operações avançadas de agrupamento e classificação em listas de arquivos ou pastas. Ele também mostra como apresentar a saída paginada na janela do console usando os métodos Skip e Take.

Exemplo

A consulta a seguir mostra como agrupar o conteúdo de uma árvore de diretório especificada pela extensão de nome de arquivo.

Module GroupByExtension
    Public Sub Main()

        ' Root folder to query, along with all subfolders.
        Dim startFolder As String = "C:\program files\Microsoft Visual Studio 9.0\VB\"

        ' Used in WriteLine() to skip over startfolder in output lines.
        Dim rootLength As Integer = startFolder.Length

        'Take a snapshot of the folder contents
        Dim dir As New System.IO.DirectoryInfo(startFolder)
        Dim fileList = dir.GetFiles("*.*", System.IO.SearchOption.AllDirectories)

        ' Create the query.
        Dim queryGroupByExt = From file In fileList _
                          Group By file.Extension.ToLower() Into fileGroup = Group _
                          Order By ToLower _
                          Select fileGroup

        ' Execute the query. By storing the result we can
        ' page the display with good performance.
        Dim groupByExtList = queryGroupByExt.ToList()

        ' Display one group at a time. If the number of
        ' entries is greater than the number of lines
        ' in the console window, then page the output.
        Dim trimLength = startFolder.Length
        PageOutput(groupByExtList, trimLength)

    End Sub

    ' Pages console display for large query results. No more than one group per page.
    ' This sub specifically works with group queries of FileInfo objects
    ' but can be modified for any type.
    Sub PageOutput(ByVal groupQuery, ByVal charsToSkip)

        ' "3" = 1 line for extension key + 1 for "Press any key" + 1 for input cursor.
        Dim numLines As Integer = Console.WindowHeight - 3
        ' Flag to indicate whether there are more results to display
        Dim goAgain As Boolean = True

        For Each fg As IEnumerable(Of System.IO.FileInfo) In groupQuery
            ' Start a new extension at the top of a page.
            Dim currentLine As Integer = 0

            Do While (currentLine < fg.Count())
                Console.Clear()
                Console.WriteLine(fg(0).Extension)

                ' Get the next page of results
                ' No more than one filename per page
                Dim resultPage = From file In fg _
                                Skip currentLine Take numLines

                ' Execute the query. Trim the display output.
                For Each line In resultPage
                    Console.WriteLine(vbTab & line.FullName.Substring(charsToSkip))
                Next

                ' Advance the current position
                currentLine = numLines + currentLine

                ' Give the user a chance to break out of the loop
                Console.WriteLine("Press any key for next page or the 'End' key to exit.")
                Dim key As ConsoleKey = Console.ReadKey().Key
                If key = ConsoleKey.End Then
                    goAgain = False
                    Exit For
                End If
            Loop
        Next
    End Sub
End Module

A saída deste programa pode ser extensa, dependendo dos detalhes do sistema de ficheiros local e da configuração do startFolder. Para habilitar a visualização de todos os resultados, este exemplo mostra como percorrer os resultados. As mesmas técnicas podem ser aplicadas ao Windows e a aplicações Web. Observe que, como o código organiza os itens em um grupo, é necessário um loop aninhado For Each. Há também alguma lógica adicional para calcular a posição atual na lista e permitir que o usuário pare a paginação e saia do programa. Nesse caso específico, a consulta de paginação é executada em relação aos resultados armazenados em cache da consulta original. Em outros contextos, como LINQ to SQL, esse cache não é necessário.

Compilar o código

Crie um projeto de aplicativo de console do Visual Basic, com uma Imports instrução para o namespace System.Linq.

Ver também

  • Last updated on