Visão geral do provedor Terraform AzAPI

O provedor AzAPI é uma camada fina sobre as APIs REST do Azure ARM. Permite-lhe gerir qualquer tipo de recurso do Azure usando qualquer versão da API, permitindo-lhe utilizar a funcionalidade mais recente dentro do Azure. AzAPI é um provedor de primeira classe projetado para ser usado sozinho ou em conjunto com o provedor AzureRM.

Benefícios de usar o provedor AzAPI

O provedor AzAPI apresenta os seguintes benefícios:

• Suporta todos os serviços de plano de controlo do Azure:
  • Pré-visualizar serviços e funcionalidades
  • Todas as versões da API
• Fidelidade total do ficheiro de estado do Terraform
  • As propriedades e os valores são guardados no estado
• Sem dependência do Swagger
• Autenticação comum e consistente do Azure
• Validação pré-verificação integrada
• Controle granular sobre o desenvolvimento da infraestrutura
• Extensão do Microsoft Terraform para Visual Studio Code

Recursos

Para permitir que você gerencie todos os recursos e recursos do Azure sem exigir atualizações, o provedor AzAPI inclui os seguintes recursos genéricos:

Para uma explicação detalhada de como funciona a estrutura do plano de dados e em que parent_id difere dos recursos do plano de controlo, veja Compreender a estrutura do plano de dados AzAPI.

Hierarquia de uso

No geral, o uso deve seguir estas etapas:

1. Comece por realizar o maior número possível de operações dentro de azapi_resource.
2. Se o tipo de recurso não existir em azapi_resource, mas se enquadrar num dos tipos suportados por azapi_data_plane_resource, utilize esse tipo.
3. Se o recurso já existir no AzureRM ou tiver uma propriedade que não pode ser acessada no azapi_resource, use azapi_update_resource para acessar essas propriedades específicas. Recursos que azapi_resource ou azapi_data_plane_resource não suportam não podem ser atualizados através deste recurso.
4. Se estiveres a tentar executar uma ação que não se baseia num recurso compatível com CRUD do Azure, azapi_resource_action é menos simples, mas azapi_update_resource é mais flexível.

Exemplos de configuração de recursos

O seguinte excerto de código configura um recurso Azure diretamente através da API ARM:

resource "azapi_resource" "publicip" {
  type      = "Microsoft.Network/Customipprefixes@2021-03-01"
  name      = "exfullrange"
  parent_id = azurerm_resource_group.example.id
  location  = "westus2"

  body = {
    properties = {
      cidr          = "10.0.0.0/24"
      signedMessage = "Sample Message for WAN"
    }
  }
}

O trecho de código a seguir configura uma propriedade de visualização para um recurso existente do AzureRM:

resource "azapi_update_resource" "test" {
  type        = "Microsoft.ContainerRegistry/registries@2020-11-01-preview"
  resource_id = azurerm_container_registry.acr.id

  body = {
    properties = {
      anonymousPullEnabled = var.bool_anonymous_pull
    }
  }
}

O trecho de código a seguir configura uma ação de recurso em um recurso existente do AzureRM:

resource "azapi_resource_action" "vm_shutdown" {
  type = "Microsoft.Compute/virtualMachines@2023-07-01"
  resource_id = azurerm_linux_virtual_machine.example.id
  action = "powerOff”
}

O trecho de código a seguir configura um recurso que não existe atualmente no provedor AzureRM devido a ser provisionado no plano de dados:

resource "azapi_data_plane_resource" "dataset" {
  type      = "Microsoft.Synapse/workspaces/datasets@2020-12-01"
  parent_id = trimprefix(data.azurerm_synapse_workspace.example.connectivity_endpoints.dev, "https://")
  name      = "example-dataset"
  body = {
    properties = {
      type = "AzureBlob",
      typeProperties = {
        folderPath = {
          value = "@dataset().MyFolderPath"
          type  = "Expression"
        }
        fileName = {
          value = "@dataset().MyFileName"
          type  = "Expression"
        }
        format = {
          type = "TextFormat"
        }
      }
      parameters = {
        MyFolderPath = {
          type = "String"
        }
        MyFileName = {
          type = "String"
        }
      }
    }
  }
}

Exemplo de uso de pré-voo

Os seguintes erros no snippet de código ocorrem durante a fase terraform plan devido à validação interna prévia da AzAPI:

provider "azapi" {
  enable_preflight = true
}
resource "azapi_resource" "vnet" {
  type      = "Microsoft.Network/virtualNetworks@2024-01-01"
  parent_id = azapi_resource.resourceGroup.id
  name      = "example-vnet"
  location  = "westus"
  body = {
    properties = {
      addressSpace = {
        addressPrefixes = [
          "10.0.0.0/160", # preflight will throw an error here
        ]
      }
    }
  }
}

Quando ativado, o pré-voo revela erros de configuração durante terraform plan em vez de apenas no momento da aplicação.

Fontes de dados

O fornecedor AzAPI suporta várias fontes de dados úteis:

Para um exemplo prático usando azapi_resource_list com filtragem JMESPath, veja Listar recursos do Azure com o AzAPI Terraform provider.

Leia um recurso existente com azapi_resource fonte de dados

A fonte de dados azapi_resource lê o estado atual de qualquer recurso Azure e expõe as suas propriedades através do atributo output. Use-o quando precisar de uma propriedade que o fornecedor AzureRM não expõe:

data "azapi_resource" "aks" {
  type      = "Microsoft.ContainerService/managedClusters@2024-02-01"
  resource_id = azurerm_kubernetes_cluster.example.id

  # Extract the OIDC issuer URL, not exposed by azurerm_kubernetes_cluster
  response_export_values = ["properties.oidcIssuerProfile.issuerURL"]
}

output "oidc_issuer_url" {
  value = data.azapi_resource.aks.output.properties.oidcIssuerProfile.issuerURL
}

usar response_export_values e JMESPath

response_export_values controla quais propriedades são extraídas da resposta bruta da API ARM e disponibilizadas no atributo output. Aceita uma lista ou um mapa:

• Lista: Especifique caminhos de propriedades JSON a extrair. Use ["*"] para exportar o corpo completo da resposta.
• Mapa: Use expressões JMESPath para filtrar e remodelar a resposta. A chave é o nome do campo de saída; o valor é a consulta JMESPath.

A forma de mapa é preferida para respostas de listas e casos em que é necessário transformar a saída:

data "azapi_resource_list" "storage_accounts" {
  type      = "Microsoft.Storage/storageAccounts@2023-01-01"
  parent_id = azurerm_resource_group.example.id

  response_export_values = {
    "names"     = "value[].name"
    "locations" = "value[].location"
  }
}

Para uma orientação completa, consulte Listar recursos Azure com o AzAPI Terraform provider.

Autenticação usando o provedor AzAPI

O provedor AzAPI habilita os mesmos métodos de autenticação que o provedor AzureRM. Para obter mais informações sobre opções de autenticação, consulte Autenticar Terraform no Azure.

Experiência e ciclo de vida do fornecedor AzAPI

Esta seção descreve algumas ferramentas para ajudá-lo a usar o provedor AzAPI.

Extensão VS Code e Language Server

A extensão Microsoft Terraform VS Code proporciona uma experiência de autoria rica tanto para os fornecedores AzureRM como AzAPI, incluindo:

• Liste todos os tipos de recursos e versões de API disponíveis.
• Autocompletar as propriedades permitidas e os respetivos valores para qualquer recurso.
• Mostrar dicas ao passar o mouse sobre um estabelecimento.
• Validação de sintaxe
• Autocompletação com exemplos de código.

A extensão também suporta paste-as-AzAPI (converte JSON ARM em blocos azapi_resource), exportação de recursos Azure via aztfexport, migração de AzureRM para AzAPI e validação pré-voo. Para um guia completo, consulte Use a extensão Microsoft Terraform VS Code.

aztfmigrate ferramenta de migração

A ferramenta aztfmigrate foi projetada para ajudar a migrar recursos existentes entre os provedores AzAPI e AzureRM.

aztfmigrate tem dois modos: planejar e migrar:

• Plan exibe os recursos AzAPI que podem ser migrados.
• Migrar migra os recursos AzAPI para recursos do AzureRM nos arquivos HCL e no estado.

aztfmigrate garante após a migração que a configuração e o estado do Terraform estejam alinhados com o seu estado real. Pode validar a atualização do estado executando terraform plan após completar a migração para confirmar que não houve alterações.

Para um guia passo a passo, consulte Migrar recursos do AzAPI para o AzureRM.

Importar recursos Azure existentes

Para colocar um recurso de Azure existente sob gestão AzAPI sem o recriar, use o bloco import (Terraform 1.5 e posteriores) ou o comando terraform import. O ID do recurso deve incluir a versão da API como parâmetro de consulta:

import {
  to = azapi_resource.example
  id = "/subscriptions/00000000-0000-0000-0000-000000000000/resourceGroups/example-rg/providers/Microsoft.Network/virtualNetworks/example-vnet?api-version=2023-11-01"
}

resource "azapi_resource" "example" {
  type      = "Microsoft.Network/virtualNetworks@2023-11-01"
  name      = "example-vnet"
  parent_id = "/subscriptions/00000000-0000-0000-0000-000000000000/resourceGroups/example-rg"
  location  = "westus"
  body = {
    properties = {
      addressSpace = {
        addressPrefixes = ["10.0.0.0/16"]
      }
    }
  }
}

Para importar múltiplos recursos ao mesmo tempo da infraestrutura de Azure existente, use Azure Export for Terraform (aztfexport), que gera automaticamente tanto a configuração HCL como os blocos de importação.

Controles granulares sobre a infraestrutura

Um grande benefício do AzAPI é através de sua capacidade de ajustar sua configuração para corresponder aos padrões de design certos. Há várias maneiras de fazer isso:

Opções de configuração do fornecedor

O bloco de fornecedores AzAPI aceita várias definições que se aplicam globalmente a todos os recursos da configuração:

Para uma lista completa das opções de configuração do fornecedor, consulte o esquema do fornecedor AzAPI.

Para uma explicação de como ativar o pré-voo, veja Ativar validação pré-voo no fornecedor AzAPI Terraform.

Funções do provedor

AzAPI v2.0 e posteriores incluem várias funções de fornecedor:

Erros que podem ser retomados definidos pelo usuário com o bloco retry

O fornecedor AzAPI trata os erros esperados através do retry bloco. Por exemplo, use a seguinte configuração para repetir quando um recurso encontrar um tempo limite de criação.

resource "azapi_resource" "example" {
    # usual properties
    retry {
        interval_seconds     = 5
        randomization_factor = 0.5 # adds randomization to retry pattern
        multiplier           = 2 # if try fails, multiplies time between next try by this much
        error_message_regex  = ["ResourceNotFound"]
    }
    timeouts {
        create = "10m"
}

O retry bloco aceita estes atributos:

Combine retry com o timeouts bloco para definir um limite superior para a duração total de tentativas:

timeouts {
  create = "10m"
}

Recursos efémeros e propriedades de escrita única

AzAPI v2.x suporta argumentos apenas de escrita (Terraform 1.11 e posteriores) através do sensitive_body atributo em azapi_resource. Propriedades apenas de escrita são enviadas para a API ARM mas não são armazenadas no estado Terraform, o que é útil para segredos e credenciais:

resource "azapi_resource" "example" {
  type      = "Microsoft.SomeService/resources@2024-01-01"
  name      = "example"
  parent_id = azurerm_resource_group.example.id

  body = {
    properties = {
      name = "example"
    }
  }

  # Write-only — not stored in state
  sensitive_body = {
    properties = {
      adminPassword = var.admin_password
    }
  }
}

Use sensitive_body_version para controlar quando propriedades apenas de escrita são reenviadas para a API (por exemplo, ao alterar credenciais).

Gatilhos para substituição de recursos

O provedor de AzAPI permite configurar parâmetros para substituição de recursos:

replace_triggers_external_values

Substitui o recurso caso um valor seja modificado. Por exemplo, se as variáveis SKU ou zones fossem modificadas, esse recurso seria recriado:

resource "azapi_resource" "example" {
  name      = var.name
  type      = "Microsoft.Network/publicIPAddresses@2023-11-01"
  parent_id = "/subscriptions/00000000-0000-0000-0000-000000000000/resourceGroups/example"
  body      = properties = {
    sku   = var.sku
    zones = var.zones
  }
  replace_triggers_external_values = [
    var.sku,
    var.zones,
  ]
}

Este gatilho funciona num conjunto amplo de recursos — por exemplo, na atribuição de uma política quando as propriedades da definição mudam.

replace_triggers_refs

Substitui o recurso se o valor referenciado mudar. Por exemplo, se o nome ou a camada da SKU fosse modificada, esse recurso seria recriado:

resource "azapi_resource" "example" {
  type      = "Microsoft.Relay/namespaces@2021-11-01"
  parent_id = azurerm_resource_group.example.id
  name      = "xxx"
  location  = "westus"
  body = {
    properties = {
    }
    sku = {
      name = "Standard"
      tier = "Standard"
    }
  }

  replace_triggers_refs = ["sku"]
}

Isto não desencadearia uma substituição se o SKU de um recurso diferente mudar.

Próximos passos

• Escolha entre fornecedores AzureRM e AzAPI Terraform
• Compreender a estrutura do plano de dados AzAPI
• Implante seu primeiro recurso com o provedor AzAPI
• Implante seu primeiro recurso de atualização com o provedor AzAPI
• Implante sua primeira ação de recurso com o provedor AzAPI
• Realizar ações de recursos com o fornecedor AzAPI
• Gerir recursos do plano de dados do Azure com AzAPI
• Liste os recursos do Azure com o fornecedor AzAPI
• Ativar a validação pré-voo
• Utilizar as funções do fornecedor AzAPI
• Caminhos de migração entre Azure, AzureRM e AzAPI
• Visite o registro do provedor