Partilhar via

Criar duas aplicações web ligadas de forma segura com Private Endpoint e integração com VNet

Este artigo ilustra um exemplo de utilização do Private Endpoint e da integração regional com VNet para ligar duas aplicações web (frontend e backend) de forma segura com a seguinte configuração Terraform:

  1. Implantar uma VNet
  2. Criar a primeira sub-rede para a integração
  3. Crie a segunda sub-rede para o endpoint privado e desative as políticas de sub-rede para endpoints privados (definido private_endpoint_network_policies_enabled = false)
  4. Implementar um plano de Serviço de Aplicação do tipo Basic, Standard, PremiumV2, PremiumV3, IsolatedV2, Functions Premium (por vezes referido como plano Elastic Premium), necessário para a funcionalidade Private Endpoint
  5. Crie a aplicação web frontend com definições específicas para consumir a zona DNS privada. Para mais informações, consulte zonas privadas Azure DNS.
  6. Liga a aplicação web frontend à sub-rede de integração
  7. Criar a aplicação web de backend
  8. Crie a zona privada DNS com o nome da zona de ligação privada para aplicações web (privatelink.azurewebsites.net)
  9. Liga esta zona ao VNet
  10. Criar o endpoint privado para a aplicação web de backend na sub-rede do ponto final e registar os nomes DNS (site e SCM) na zona privada DNS previamente criada

Como usar o terraform no Azure

Consulte a documentação do Azure para saber como usar o terraform com Azure.

O arquivo completo de Terraform

Para usar este ficheiro, substitua os marcadores <nome-unico-aplicacao-frontend> e <nome-unico-aplicacao-backend> (o nome da aplicação é usado para formar um nome DNS único em todo o mundo).

terraform {
  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = "~> 3.0"
    }
  }
}

provider "azurerm" {
  features {}
}

resource "azurerm_resource_group" "rg" {
  name     = "appservice-rg"
  location = "francecentral"
}

resource "azurerm_virtual_network" "vnet" {
  name                = "vnet"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  address_space       = ["10.0.0.0/16"]
}

resource "azurerm_subnet" "integrationsubnet" {
  name                 = "integrationsubnet"
  resource_group_name  = azurerm_resource_group.rg.name
  virtual_network_name = azurerm_virtual_network.vnet.name
  address_prefixes     = ["10.0.1.0/24"]

  delegation {
    name = "delegation"

    service_delegation {
      name = "Microsoft.Web/serverFarms"
    }
  }
}

resource "azurerm_subnet" "endpointsubnet" {
  name                 = "endpointsubnet"
  resource_group_name  = azurerm_resource_group.rg.name
  virtual_network_name = azurerm_virtual_network.vnet.name
  address_prefixes     = ["10.0.2.0/24"]

  private_endpoint_network_policies_enabled = false
}

resource "azurerm_service_plan" "appserviceplan" {
  name                = "appserviceplan"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  os_type             = "Windows"
  sku_name            = "P1v2"
}

resource "azurerm_windows_web_app" "frontwebapp" {
  name                = "<unique-frontend-app-name>"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  service_plan_id     = azurerm_service_plan.appserviceplan.id

  site_config {}

  app_settings = {
    "WEBSITE_DNS_SERVER"     = "168.63.129.16"
    "WEBSITE_VNET_ROUTE_ALL" = "1"
  }
}

resource "azurerm_app_service_virtual_network_swift_connection" "vnetintegrationconnection" {
  app_service_id = azurerm_windows_web_app.frontwebapp.id
  subnet_id      = azurerm_subnet.integrationsubnet.id
}

resource "azurerm_windows_web_app" "backwebapp" {
  name                = "<unique-backend-app-name>"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  service_plan_id     = azurerm_service_plan.appserviceplan.id

  site_config {}
}

resource "azurerm_private_dns_zone" "dnsprivatezone" {
  name                = "privatelink.azurewebsites.net"
  resource_group_name = azurerm_resource_group.rg.name
}

resource "azurerm_private_dns_zone_virtual_network_link" "dnszonelink" {
  name                  = "dnszonelink"
  resource_group_name   = azurerm_resource_group.rg.name
  private_dns_zone_name = azurerm_private_dns_zone.dnsprivatezone.name
  virtual_network_id    = azurerm_virtual_network.vnet.id
}

resource "azurerm_private_endpoint" "privateendpoint" {
  name                = "backwebappprivateendpoint"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  subnet_id           = azurerm_subnet.endpointsubnet.id

  private_dns_zone_group {
    name                 = "privatednszonegroup"
    private_dns_zone_ids = [azurerm_private_dns_zone.dnsprivatezone.id]
  }

  private_service_connection {
    name                           = "privateendpointconnection"
    private_connection_resource_id = azurerm_windows_web_app.backwebapp.id
    subresource_names              = ["sites"]
    is_manual_connection           = false
  }
}

Passos seguintes

Saiba mais sobre como usar o Terraform no Azure

  • Last updated on