Consultas de exemplo do inventário do Power Platform

As consultas de exemplo a seguir são executadas na tabela PowerPlatformResources em Azure Resource Graph. Elas abrangem contagem e distribuição de recursos, descoberta de campo, pesquisas de recursos e análise de uso do conector. Para obter uma visão geral do inventário do Power Platform, consulte o inventário do Power Platform. Para obter a referência de esquemas e campos, consulte a referência do esquema de inventário do Power Platform.

Como executar essas consultas

Você pode executar qualquer uma dessas consultas nas interfaces Azure Resource Graph. Para obter instruções passo a passo, confira os seguintes guias de início rápido:

Contagens e distribuição

Contagem total de todos os recursos

PowerPlatformResources
| count

Total de contagens por tipo de recurso

PowerPlatformResources
| summarize resourceCount = count() by type
| order by resourceCount

Contagens por ambiente

PowerPlatformResources
| extend properties = parse_json(properties)
| extend environmentId = tostring(properties.environmentId)
| summarize resourceCount = count() by environmentId
| order by resourceCount desc

Contagens por região

PowerPlatformResources
| summarize resourceCount = count() by location
| order by resourceCount desc

Principais proprietários por contagem de itens

PowerPlatformResources
| extend properties = parse_json(properties)
| extend ownerId = tostring(properties.ownerId)
| summarize resourceCount = count() by ownerId
| order by resourceCount desc

Pesquisas de recursos

Localizar um único agente no locatário

PowerPlatformResources
| where type == "microsoft.copilotstudio/agents"
| where name == "[Enter the agent's ID]"

Dica

Você pode encontrar a ID do agente na URL do Copilot Studio ao exibir o agente ou na coluna Name da tabela de inventário.

Itens criados nas últimas 24 horas

PowerPlatformResources
| extend properties = parse_json(properties)
| extend createdAt = todatetime(properties.createdAt)
| where createdAt >= ago(24h)

Consultas de conector (versão prévia)

As consultas a seguir analisam o uso do conector entre os tipos de recursos cobertos pelo inventário do Conector (versão prévia). Cada consulta opera sobre o array properties.powerPlatformConnectors gerado por aplicativos de tela, aplicativos orientados por modelo, fluxos de nuvem, fluxos de agente, fluxos de agente de fluxo de trabalho e agentes do Copilot Studio.

Principais conectores usados em recursos do Power Platform

Lista os conectores usados pelos recursos mais distintos. Útil para entender quais conectores lideram a adoção em todo o tenant.

PowerPlatformResources
| where type in (
    "microsoft.powerapps/canvasapps",
    "microsoft.powerapps/modeldrivenapps",
    "microsoft.powerautomate/cloudflows",
    "microsoft.powerautomate/agentflows",
    "microsoft.powerautomate/m365agentflows",
    "microsoft.copilotstudio/agents")
| extend properties = parse_json(properties)
| mv-expand connector = properties.powerPlatformConnectors
| extend connectorId = tostring(connector.connectorId)
| where isnotempty(connectorId)
| summarize ResourceCount = dcount(name) by connectorId
| order by ResourceCount desc
| take 10

Distribuição da contagem de conectores por recurso

Mostra quantos recursos usam 0, 1, 2 ou mais conectores. Útil para detectar exceções de complexidade.

PowerPlatformResources
| where type in (
    "microsoft.powerapps/canvasapps",
    "microsoft.powerapps/modeldrivenapps",
    "microsoft.powerautomate/cloudflows",
    "microsoft.powerautomate/agentflows",
    "microsoft.powerautomate/m365agentflows",
    "microsoft.copilotstudio/agents")
| extend properties = parse_json(properties)
| extend connectorCount = array_length(properties.powerPlatformConnectors)
| summarize ResourceCount = count() by toint(connectorCount)
| order by connectorCount asc

Localizar todos os recursos que usam um conector específico

Substitua shared_sharepointonline pelo conector que você deseja pesquisar. Essa consulta é útil para análise de impacto quando um conector tem um problema conhecido, está sendo preterido ou requer um novo licenciamento.

PowerPlatformResources
| where type in (
    "microsoft.powerapps/canvasapps",
    "microsoft.powerapps/modeldrivenapps",
    "microsoft.powerautomate/cloudflows",
    "microsoft.powerautomate/agentflows",
    "microsoft.powerautomate/m365agentflows",
    "microsoft.copilotstudio/agents")
| extend properties = parse_json(properties)
| mv-expand connector = properties.powerPlatformConnectors
| where tostring(connector.connectorId) == "shared_sharepointonline"
| project resourceName = tostring(properties.displayName),
          resourceId = name,
          resourceType = type,
          environmentId = tostring(properties.environmentId),
          operationsUsed = connector.operations

Uso do conector por ambiente

Lista todos os conectores usados em cada ambiente, com a contagem de recursos distintos que o usam. Essa lista é útil para entender os padrões de adoção e informar as decisões de política DLP.

PowerPlatformResources
| where type in (
    "microsoft.powerapps/canvasapps",
    "microsoft.powerapps/modeldrivenapps",
    "microsoft.powerautomate/cloudflows",
    "microsoft.powerautomate/agentflows",
    "microsoft.powerautomate/m365agentflows",
    "microsoft.copilotstudio/agents")
| extend properties = parse_json(properties)
| mv-expand connector = properties.powerPlatformConnectors
| extend connectorId = tostring(connector.connectorId)
| where isnotempty(connectorId)
| extend environmentId = tostring(properties.environmentId)
| summarize ResourceCount = dcount(name) by environmentId, connectorId
| order by environmentId asc, ResourceCount desc

Conteúdo relacionado

  • Last updated on