Guia de Início Rápido: Executar ações de recursos do Azure com o provedor Terraform do AzAPI

O Terraform permite a definição, a visualização e a implantação da infraestrutura de nuvem. Usando o Terraform, você cria arquivos de configuração usando a sintaxe HCL. A sintaxe da HCL permite que você especifique o provedor de nuvem, como o Azure, e os elementos que compõem sua infraestrutura de nuvem. Depois de criar os arquivos de configuração, você cria um plano de execução que permite visualizar as alterações de infraestrutura antes de serem implantadas. Depois de verificar as alterações, você aplica o plano de execução para implantar a infraestrutura.

Use azapi_resource_action como um recurso Terraform gerenciado para executar operações imperativas de alteração de estado em recursos Azure. Neste exemplo, você cria uma conta de armazenamento Azure e, em seguida, gira suas chaves de acesso.

azapi_resource_action tem dois formulários de uso:

  • Recurso: executa uma operação de alteração de estado durante terraform apply. O Terraform controla a ação no estado e, opcionalmente, pode revertê-la em terraform destroy.
  • Fonte de dados: executa uma operação somente leitura durante o planejamento. Consulte o guia de início rápido da fonte de dados de ação de recurso para esse cenário.

Use o formulário de recursos quando precisar do Terraform para operar no Azure em uma operação que não se baseia em um ciclo de vida padrão de criação/leitura/atualização/exclusão, por exemplo, rodar credenciais, iniciar ou parar uma VM ou acionar um failover.

  • Criar uma conta de armazenamento com o provedor do AzureRM
  • Girar a chave de acesso da conta de armazenamento com azapi_resource_action

Pré-requisitos

  • Assinatura do Azure: Se você não tiver uma assinatura do Azure, crie uma conta gratuita antes de começar.

Quando você faz logon no portal do Azure com uma conta da Microsoft, a assinatura padrão do Azure para essa conta é usada.

O Terraform autentica automaticamente usando informações da assinatura padrão do Azure.

Execute az account show para verificar a conta atual da Microsoft e a assinatura do Azure.

az account show

Todas as alterações feitas por meio do Terraform estão na assinatura exibida do Azure. Se é isso que você quer, ignore o restante deste artigo.

Implementar o código Terraform

  1. Crie um diretório em que você vai testar o código de exemplo do Terraform, depois transforme-o no diretório atual.

  2. Crie um arquivo chamado providers.tf e insira o seguinte código:

    terraform {
  required_providers {
    azapi = {
      source  = "Azure/azapi"
      version = "~> 2.0"
    }
    azurerm = {
      source  = "hashicorp/azurerm"
      version = "~> 4.0"
    }
    random = {
      source  = "hashicorp/random"
      version = "~> 3.0"
    }
  }
}

provider "azurerm" {
  features {}
}

provider "azapi" {}

  3. Crie um arquivo chamado variables.tf e insira o seguinte código:

    variable "resource_group_location" {
  type        = string
  default     = "eastus"
  description = "Location of the resource group."
}

variable "resource_group_name_prefix" {
  type        = string
  default     = "rg"
  description = "Prefix of the resource group name that's combined with a random value to create a unique name."
}

variable "storage_account_name_prefix" {
  type        = string
  default     = "st"
  description = "Prefix of the storage account name that's combined with a random value to create a unique name."
}

  4. Crie um arquivo chamado main.tf e insira o seguinte código:

    resource "random_pet" "rg_name" {
  prefix = var.resource_group_name_prefix
}

resource "random_string" "storage_suffix" {
  length  = 8
  upper   = false
  special = false
}

resource "azurerm_resource_group" "example" {
  location = var.resource_group_location
  name     = random_pet.rg_name.id
}

resource "azurerm_storage_account" "example" {
  name                     = "${var.storage_account_name_prefix}${random_string.storage_suffix.result}"
  resource_group_name      = azurerm_resource_group.example.name
  location                 = azurerm_resource_group.example.location
  account_tier             = "Standard"
  account_replication_type = "LRS"
}

resource "azapi_resource_action" "regenerate_key" {
  type        = "Microsoft.Storage/storageAccounts@2023-01-01"
  resource_id = azurerm_storage_account.example.id
  action      = "regenerateKey"
  method      = "POST"

  body = {
    keyName = "key1"
  }
}

    Principais pontos sobre como usar azapi_resource_action como um recurso:

    • O action campo especifica a operação ARM a ser executada. Para rotação de chave de conta de armazenamento, use regenerateKey.
    • O method campo especifica o método HTTP. A maioria das ações imperativas usa POST.
    • O body atributo passa dados para a ação. Para regeneração de chave, especifique qual chave (key1 ou key2) girar.
    • A ação é executada durante terraform apply e rastreada no estado do Terraform.

  5. Crie um arquivo chamado outputs.tf e insira o seguinte código:

    output "resource_group_name" {
  value = azurerm_resource_group.example.name
}

output "storage_account_name" {
  value = azurerm_storage_account.example.name
}

Execute terraform init para inicializar a implantação do Terraform. Esse comando baixa o provedor de Azure necessário para gerenciar seus recursos de Azure.

terraform init -upgrade

Pontos principais:

  • O parâmetro -upgrade atualiza os plug-ins do provedor necessários para a versão mais recente que esteja em conformidade com as restrições de versão da configuração.

Execute o comando terraform plan para criar um plano de execução.

terraform plan -out main.tfplan

Pontos principais:

  • O comando terraform plan cria um plano de execução, mas não o executa. Em vez disso, ele determina quais ações são necessárias para criar a configuração especificada em seus arquivos de configuração. Esse padrão permite verificar se o plano de execução corresponde às suas expectativas antes de fazer alterações nos recursos reais.
  • O parâmetro opcional -out permite que você especifique um arquivo de saída para o plano. Usar o parâmetro -out garante que o plano que você examinou seja exatamente o que é aplicado.

Execute o comando terraform apply para aplicar o plano de execução à sua infraestrutura de nuvem.

terraform apply main.tfplan

Pontos principais:

  • O comando de exemplo terraform apply pressupõe que você executou terraform plan -out main.tfplananteriormente.
  • Se você especificou um nome de arquivo diferente para o parâmetro -out, use esse mesmo nome de arquivo na chamada para terraform apply.
  • Se você não usou o parâmetro -out, chame terraform apply sem nenhum parâmetro.

Verifique os resultados

Após terraform apply a conclusão, a chave da conta de armazenamento foi girada. Você pode verificar a rotação de chaves verificando as chaves da conta de armazenamento no Azure.

Execute o comando az storage account keys list para visualizar as chaves da conta de armazenamento.

az storage account keys list \
  --resource-group <resource_group_name> \
  --account-name <storage_account_name>

O value campo mostra a chave atual.

Exemplos de outras ações de recursos

O recurso azapi_resource_action funciona com muitas operações de Azure. Aqui estão exemplos comuns:

  • Máquinas Virtuais: deallocate, start, restart, powerOff, reimage
  • Key Vaults: purge (para cofres com exclusão reversível) rotate (para chaves gerenciadas)
  • Serviços de Aplicativo: swap (para slots de implantação), restart
  • Bancos de dados: failover, promote
  • Compute resources: qualquer operação exposta pela API REST Azure que modifica o estado sem criar ou destruir um recurso

Limpar os recursos

Quando você não precisar mais dos recursos criados por meio do Terraform, execute as seguintes etapas:

  1. Execute o comando terraform plan e especifique a flag destroy.

    terraform plan -destroy -out main.destroy.tfplan

    Pontos principais:

    • O comando terraform plan cria um plano de execução, mas não o executa. Em vez disso, ele determina quais ações são necessárias para criar a configuração especificada em seus arquivos de configuração. Esse padrão permite verificar se o plano de execução corresponde às suas expectativas antes de fazer alterações nos recursos reais.
    • O parâmetro opcional -out permite que você especifique um arquivo de saída para o plano. Usar o parâmetro -out garante que o plano que você examinou seja exatamente o que é aplicado.

  2. Execute o comando terraform apply para aplicar o plano de execução.

    terraform apply main.destroy.tfplan

Solucionar problemas do Terraform no Azure

Solucionar problemas comuns ao usar o Terraform no Azure

Próximas Etapas 

Visão geral do provedor AzAPI do Terraform

Saiba como usar a ação de recurso AzAPI como uma fonte de dados

  • Last updated on