Gerar arquivos Bicep usando o GitHub Copilot para Azure

Há muitas maneiras de criar novos recursos no Azure. Os arquivos Bicep fornecem uma abordagem declarativa, modular e reutilizável para definir os recursos do Azure. Os modelos do Bicep oferecem melhor legibilidade, facilidade de manutenção e integração nativa com o Azure Resource Manager (ARM) em comparação com modelos ARM baseados em JSON ou métodos de script imperativos, como PowerShell e Azure CLI. O GitHub Copilot para Azure pode ajudá-lo a criar arquivos Bicep.

Gerar arquivos Bicep

Começar a usar os arquivos do Bicep pode exigir algum aprendizado se você for novo na sintaxe, mas ferramentas como o GitHub Copilot para Azure podem ajudar.

Cenário de exemplo

Suponha que você queira uma maneira fácil de criar um processo automatizado e repetível para criar um contêiner Blob e um compartilhamento de arquivos. Talvez você saiba como criar um contêiner Blob e um compartilhamento de arquivos usando o portal do Azure, mas não sabe como usar os arquivos Bicep para realizar a mesma tarefa.

Exemplo de solicitação

Crie um novo bate-papo (Ctrl + L) e, em seguida, copie e cole o seguinte prompt no painel de bate-papo do GitHub Copilot.

Show me a Bicep file that creates an Azure Storage account with a blob container and a file share.

Resposta de exemplo

O GitHub Copilot para Azure gera um arquivo Bicep semelhante ao exemplo a seguir.

@description('Specifies the name of the Azure Storage account.')
param storageAccountName string

@description('Specifies the name of the blob container to create.')
param blobContainerName string

@description('Specifies the name of the file share to create.')
param fileShareName string

@description('Specifies the location in which the Azure Storage resources should be deployed.')
param location string = resourceGroup().location

resource sa 'Microsoft.Storage/storageAccounts@2023-01-01' = {
  name: storageAccountName
  location: location
  sku: {
    name: 'Standard_LRS'
  }
  kind: 'StorageV2'
  properties: {
    accessTier: 'Hot'
  }
}

resource blobServices 'Microsoft.Storage/storageAccounts/blobServices@2023-01-01' = {
  parent: sa
  name: 'default'
}

resource blobContainer 'Microsoft.Storage/storageAccounts/blobServices/containers@2023-01-01' = {
  parent: blobServices
  name: blobContainerName
  properties: {
    publicAccess: 'None'
  }
}

resource fileServices 'Microsoft.Storage/storageAccounts/fileServices@2023-01-01' = {
  parent: sa
  name: 'default'
}

resource fileShare 'Microsoft.Storage/storageAccounts/fileServices/shares@2023-01-01' = {
  parent: fileServices
  name: fileShareName
  properties: {
    shareQuota: 100 // Quota in MB
  }
}

Crie um novo arquivo main.bicep, copie a resposta do GitHub Copilot for Azure e cole no novo arquivo.

Ao usar a CLI do Azure para executar o arquivo Bicep, você pode definir os parâmetros declarados como storageAccountName, blobContainerName, e fileShareName.

Como alternativa, você pode editar o arquivo do Bicep inicializando o parâmetro storageAccountName para o valor desejado.

param storageAccountName string = '<your-storage-account-name>'

Refinar a resposta

No entanto, se você for novo nos arquivos Bicep, talvez precise de mais informações. Continue interagindo na mesma sessão de chat para entender as próximas etapas.

Por exemplo, você pode perguntar onde esse arquivo Bicep deve ser criado em seu espaço de trabalho do VS Code.

Where in my workspace should I create the Azure Bicep file, and what should I call it?

Ele poderá responder sugerindo uma pasta e um nome de arquivo para seu novo arquivo do Bicep. Por exemplo, infra/storageAccount.bicep.

Por fim, se não tiver certeza de como implantar o arquivo do Bicep, você pode criar um prompt que solicite instruções.

How do I execute the Azure Bicep file?

Você pode receber uma resposta semelhante à seguinte.

To execute the Bicep file, you can use the Azure CLI with the following steps:

1. **Install Azure CLI and Bicep CLI**: Ensure you have the Azure CLI and Bicep CLI installed. You can install Bicep using the Azure CLI with the command:

   az bicep install


2. **Log in to Azure**: Use the Azure CLI to log in to your Azure account:

   az login


3. **Deploy the Bicep file**: Use the `az deployment group create` command to deploy the Bicep file to a resource group. Replace `<resource-group-name>` with your resource group name and `<location>` with your desired Azure region:
  
   az deployment group create --resource-group <resource-group-name> --template-file infra/storageAccount.bicep --parameters storageAccountName=<your-storage-account-name> containerName=<your-container-name> fileShareName=<your-file-share-name> location=<location>


This command will deploy the resources defined in your Bicep file to the specified resource group in Azure.

Ao seguir estas instruções, se você ficar preso ou encontrar um problema, continue fazendo perguntas ao GitHub Copilot e crie prompts que incluam a palavra azure no painel de chat.

Conteúdo relacionado

• Visão geral do Bicep
• O que é o GitHub Copilot para o Azure?
• Introdução ao GitHub Copilot para Azure