日付の有効期間

注

コミュニティの関心グループが Yammer から Microsoft Viva Engage に移行されました。 Viva Engage コミュニティに参加し、最新のディスカッションに参加するには、「 Finance and Operations Viva Engage Community へのアクセスを要求する」フォームに入力し、参加するコミュニティを選択します。

この記事では、日付に基づいて有効なデータエンティティとデータソースに関する情報を提供し、日付有効エンティティを作成する方法を示します。また、日付の有効性が読み取りおよび書き込みアクティビティに適用される方法についても説明します。

データエンティティを含む日付効果の高い機能には、さまざまな設計パターンが存在します。これらのパターンは、次の 2 つの主要なカテゴリに分類されます。

有効日エンティティ - エンティティには少なくとも 1 つの有効日データソースがあり、エンティティ自体も日付が有効です。
非日付有効エンティティ – エンティティ自体は有効な日付ではありませんが、日付有効なデータソースが含まれています。

次のセクションでは、エンティティとその日付有効データソースの日付有効動作を制御するプロパティとメソッドについて説明します。

有効日のエンティティ

次のテーブルは、データエンティティの日付を有効にする操作を制御するプロパティを示しています。

エンティティのプロパティ名	プロパティのノード	値	説明
ValidTimeStateEnabled	デザイナーのデータエンティティノード	はい (またはいいえ)	値 Yes は、エンティティの日付を有効にします。エンティティには、ValidFrom および ValidTo フィールドが必要です。これらのフィールドは、日付有効データソースの ValidFrom フィールドと ValidTo フィールドにマップされます。値 No は、エンティティのデータソースである日付有効テーブルに対する日付の有効性の適用を無効にしません。
ValidTimeStateKey	データエンティティノードの下の、キー>EntityKey	はい (またはいいえ)	値 Yes は、この特定のエンティティに日付有効値を適用するキーを識別します。

リーディングアクティビティ

データエンティティレベルで日付の有効性を設定すると、エンティティからの読み取りはテーブルからの読み取りと同じように動作します。エンティティには、システムが読み込み中に日付フィルターを適用する ValidFrom および ValidTo フィールドがあります。

クエリモードとX++ SQLのvalidtimestateキーワード

日付有効なエンティティは、X++ validtimestate キーワードの使用方法が異なる次の 3 つのクエリモードをサポートします。

既定のモード – select * from FMVehicleRateEntity; // X++ SQL.を使用して現在のレコードを返します。
AsOfDate モード – 指定した日付に対して有効なレコードを返します。 select validtimestate(d1) * from FMVehicleRateEntity;
AsOfDateRange モード – 指定した日付範囲に対して有効なレコードを返します。 select validtimestate(d1,d2) * from FMVehicleRateEntity;

重要： 日付が有効なエンティティではなく、日付が有効なデータソースを持つデータエンティティの場合は、既定のクエリモードのみ使用できます。この概念については、この記事の後半で説明します。

データソースレベルで日付フィルターを適用する

一部のシナリオでは、データソースレベルで、データエンティティの外部で日付有効なフィルター処理が必要です。たとえば、顧客エンティティ (CustTableTestEntity) にはデータソースとして CustTable および LogisticsPostalAddress が含まれています。LogisticsPostalAddress は日付の有効なテーブルであり、CustTable は通常のテーブルです。顧客エンティティの目的は、顧客とそのアクティブなプライマリアドレスのリスト (プライマリアドレスがある場合) を含めることです。したがって、顧客エンティティ自体は日付有効ではありませんが、データソースの 1 つに日付フィルターが必要です。この場合は、エンティティ ValidTimeStateEnabled をマークしないでください。代わりに、データソースに [日付フィルターの適用] プロパティを追加します。 [ 日付フィルターの適用 ] の値を [はい] に設定すると、そのデータソースに日付フィルターが自動的に適用されます。次のテーブルでは、データエンティティの有効日データソースの有効日動作を制御するプロパティについて説明します。

データソースのプロパティ名	プロパティのノード	値	説明
日付フィルターの適用	エンティティの特定のデータソースのノード	はい (またはいいえ)	読み取りの場合、このプロパティは、システムがエンティティデータソースに日付フィルターを適用するかどうかを制御します。この場合は、データソース ValidTimeStateEnabled をマークします。このプロパティ値は、エンティティ自体が日付有効であるかどうかにかかわらず有効です。書き込みで、このプロパティは影響を与えません。

この記事では、これらの日付が有効なプロパティの使用方法とそれらの相互作用について説明します。

読み取り用の状態行列

このセクションは、データエンティティからの読み取りのみに関係します。次の参照マトリックスのペアでは、データエンティティとそのデータソースの間に存在できる日付有効状態の組み合わせについて説明します。各テーブルには、4 つのクラスが含まれ、各ケースでは、2 つの異なるターゲットについて説明します。理解しておく必要がある主要なポイントを次に示します。

エンティティからの任意の読み取りにおいて、クエリモードはエンティティと有効日データソースの両方で同じです。
エンティティが有効な日付でない場合、クエリモードは既定のモードに制限されます。したがって、日付が有効なデータソースは現在の日付のみにアクセスされます。
日付有効データソースで、[ 日付フィルターの適用 ] プロパティを [いいえ ] に設定して、データソースが過去、現在、および将来のすべてのデータを返すようにします。
OData の場合、日付有効フィルターはデータエンティティに適用されません。ただし、データソースのフィルターはすべてのコードパスに適用されます。

A. エンティティは有効日である、なぜならば ValidTimeStateEnabled = はい

データソースは日付が有効です

データソースは日付が有効ではない

日付フィルターの適用 = はい

エンティティ 日付フィルターが適用されます。すべてのクエリモードがサポートされています。
データソース: フィルターが適用されます。クエリモードはサポートされていますが、モードはエンティティのコードと同じです。

有効日の対象外のデータソースは影響しません。

日付フィルターの適用 = いいえ

エンティティ 日付フィルターが適用されます。すべてのクエリモードがサポートされています。
データソース: 日付フィルターは適用されません。

有効日の対象外のデータソースは影響しません。

B. エンティティは日付で有効ではありません、これは ValidTimeStateEnabled = いいえによるものです。

データソースは日付によって有効

データソースは日付が有効ではない

日付フィルターの適用 = はい

エンティティ 日付フィルターが適用されません。
データソース: 日付フィルターが適用されます。既定のクエリモードのみサポートされ、X++ validtimestate キーワードは省略されます。

有効日の対象外のデータソースは影響しません。

日付フィルターの適用 = いいえ

エンティティ 日付フィルターが適用されません。
データソース: 日付フィルターは適用されません。

有効日の対象外のデータソースは影響しません。

次のスクリーンショットは、[ 日付フィルターの適用] プロパティが [はい] に設定されている状態を示しています。そのため、日付フィルターは アドレス データソースの読み取りに適用されます。

活動の記述

このセクションでは、有効日エンティティとその有効日データソースの動作を設定するオプションについて説明します。まず、日付有効テーブルの概念を確認し、日付有効エンティティと比較します。 日付有効テーブル: 日付有効テーブルにデータを挿入または更新する場合は、テーブルバッファーで xRecord.validTimeStateUpdateMode メソッドを呼び出すことができます。このメソッドは、ValidTimeStateUpdate 列挙型の要素を受け入れます。使用可能な要素値を次に示します。

新しい時間の期間を作成
訂正
EffectiveBased

日付有効エンティティ: これに対し、日付有効データエンティティにデータを挿入または更新する場合は、エンティティレベルで validTimeStateUpdateMode メソッドを使用しないでください。書き込みについては、データエンティティは日付有効処理をテーブルレベルに委ねます。エンティティデータソースの Valid Time State Update プロパティを使用して、データエンティティの各データソースに使用する validTimeStateUpdateMode メソッドを指定します。

日付有効なエンティティを作成しています

このセクションでは、有効日のあるエンティティを作成する方法を示します。

新しいプロジェクトの作成

[ファイル>新規作成>プロジェクトを選択して新しいプロジェクトを作成します。
ソリューションエクスプローラーで、プロジェクトを右クリックしてから [プロパティ] を選択します。プロジェクトの プロパティページ ダイアログボックスが開きます。
[ビルド時にデータベースを同期する] プロパティの値を True に変更し、[OK] を選択します。このプロパティは、プロジェクトごとに 1 回だけ設定します。

プロジェクトへの新しいデータエンティティの追加

FMVehicleRateEntity という名前の新しいエンティティを作成し、プロジェクトに追加します。

左側のウィンドウで、[ Microsoft Dynamics 365 Artifacts] を選択し、メインウィンドウの左側の列にある [データエンティティ ] を選択します。
[] を選択し、[] を追加します。 データエンティティビュー ウィザードが起動します。
次のスクリーンショットに示すように、作成するデータエンティティのプロパティ値を指定します。最も重要なフィールドは、FMVehicleRate を選択する プライマリデータソース です。

[ 次へ] を選択します。
プライマリデータソース、FMVehicleRate からエンティティにフィールドを追加します。
すべてのフィールドを選択し、[ 完了] を選択します。

項目は ソリューションエクスプローラーでプロジェクトに追加されます。

プロジェクトの構築

[ ビルド>ビルドソリューション ] を選択してプロジェクトをビルドします。
ビルドにエラーが含まれていないことを確認します。この段階では、警告は許容されます。

プロパティ値の検証

ソリューションエクスプローラーで FMVehicleRateEntity ノードを選択し、[プロパティ] ウィンドウの値と比較して FMVehicleRateEntity エンティティのプロパティを検証します。

エンティティの日付を有効にする

ソリューションエクスプローラーで、FMVehicleRateEntity ノードを右クリックし、[開く] を選択します。エンティティのデザイナーが中央のウィンドウに表示されます。
時間状態が有効であるかどうかを検証するプロパティの値をはいに変更します。

日付有効データソースの有効時間状態更新プロパティを構成する

FMVehicleRate データソースを選択し、有効時間状態の更新 プロパティを CreateNewTimePeriod に設定します。

プロジェクトをテスト

プロジェクトを再度構築し、次の X++ コードを実行してプロジェクトをテストします。

/// <summary>
    /// Runs the class with the specified arguments.
    /// </summary>
    /// <param name = "_args">The specified arguments.</param>
    public static void main(Args _args)
    {
        FMVehicleRateEntity FMVehicleRateEntity;
        FMCarClass          vehicle;
        FMVehicleModel      model;
        FMVehicleRate       vehicleRateTable;
        TransDate           d1=1\1\1999,d2=31\12\2014;

        ttsbegin;

        select count(RecId) from FMVehicleRateEntity;
        info(strfmt("Entity - Valid today before insert %1",FMVehicleRateEntity.RecId));

        select count(RecId) from vehicleRateTable;
        info(strfmt("Table - Valid today before insert %1",vehicleRateTable.RecId));

        select firstonly model;

        vehicle.VehicleModel = model.RecId;
        vehicle.VehicleId = "TestV1001";
        vehicle.insert();

            if (vehicle)
            {
                FMVehicleRateEntity.clear();
                FMVehicleRateEntity.FMVehicle_VehicleId = vehicle.VehicleId;
                FMVehicleRateEntity.ValidFrom = d1;
                FMVehicleRateEntity.ValidTo = d2;
                FMVehicleRateEntity.RatePerDay = 100;
                FMVehicleRateEntity.RatePerWeek = 600;
                FMVehicleRateEntity.insert();

                // Should increase by one as compared to before insert numbers
                select count(RecId) from FMVehicleRateEntity;
                info(strfmt("Entity - Valid today after insert %1",FMVehicleRateEntity.RecId));

                // Should increase by one as compared to before insert numbers
                select count(RecId) from vehicleRateTable;
                info(strfmt("Table - Valid today after insert %1",vehicleRateTable.RecId));

                // New record should show in count
                select validtimestate(d1) count(RecId) from FMVehicleRateEntity;
                info(strfmt("Entity - Valid 1999 %1",FMVehicleRateEntity.RecId));

                // New record should show in count
                select validtimestate(d1) count(RecId) from vehicleRateTable;
                info(strfmt("Table - Valid 1999 %1",vehicleRateTable.RecId));

                // update newly created record
                // This should split record into two - 2009 to Today, today to 2014
                // Split happens because of mode in saveEntityDatasource
                select forupdate validtimestate(d1,d2) FMVehicleRateEntity 
                     where FMVehicleRateEntity.FMVehicle_VehicleId == vehicle.VehicleId &&
                           FMVehicleRateEntity.ValidFrom == d1 &&
                           FMVehicleRateEntity.ValidTo == d2;
                FMVehicleRateEntity.RatePerDay = 200;
                FMVehicleRateEntity.update();

                // validate the split
                while select validtimestate(d1,d2) FMVehicleRateEntity
                     where FMVehicleRateEntity.FMVehicle_VehicleId == vehicle.VehicleId
                {
                    info(strfmt("Entity - %1 to %2 , RatePerDay-%3, RatePerWeek-%4",
                            FMVehicleRateEntity.ValidFrom,
                            FMVehicleRateEntity.ValidTo,
                            FMVehicleRateEntity.RatePerDay,
                            FMVehicleRateEntity.RatePerWeek));
                }
                ttsabort;
            }
        }

フィードバック

このページはお役に立ちましたか?

Last updated on 2026-04-01

次の方法で共有

日付の有効期間

有効日のエンティティ

リーディングアクティビティ

クエリモードとX++ SQLのvalidtimestateキーワード

データ ソース レベルで日付フィルターを適用する

読み取り用の状態行列

活動の記述

日付有効なエンティティを作成しています

新しいプロジェクトの作成

プロジェクトへの新しいデータ エンティティの追加

プロジェクトの構築

プロパティ値の検証

エンティティの日付を有効にする

日付有効データソースの有効時間状態更新プロパティを構成する

プロジェクトをテスト

フィードバック

その他のリソース

データソースレベルで日付フィルターを適用する

プロジェクトへの新しいデータエンティティの追加