クイックスタート: Bicep ファイルの展開のトラブルシューティング

このクイックスタートでは、Bicepファイル展開エラーのトラブルシューティング方法について説明します。エラーを含むファイルを作成し、エラーを修正する方法について説明します。

デプロイに関するエラーには 3 種類あります。

検証エラー は、デプロイが開始される前に発生し、ファイル内の構文エラーが原因で発生します。 Visual Studio Codeのようなコードエディターでは、これらのエラーを識別できます。
プレフライト検証エラー は、デプロイコマンドが実行されていてもリソースがデプロイされていない場合に発生します。これらのエラーは、デプロイを開始しなくても検出されます。たとえば、パラメーター値が正しくない場合、エラーはプレフライト検証で見つかります。
デプロイエラーはデプロイプロセス中に発生し、Azure環境でのデプロイの進行状況を評価することによってのみ確認できます。

どの種類のエラーでも、デプロイのトラブルシューティングに使用できるエラーコードが出力されます。検証とプレフライトのエラーはアクティビティログに表示されますが、デプロイ履歴には表示されません。構文エラーが発生したBicep ファイルは JSON にコンパイルされず、アクティビティログには表示されません。

[前提条件]

このクイックスタートを実行するには、次のものが必要です。

Azureサブスクリプションをお持ちでない場合は、開始する前に無料アカウントを作成してください。
Visual Studio Codeの最新のBicep拡張機能。
最新バージョンの Azure PowerShell または Azure CLI。

エラーが発生したBicep ファイルを作成する

次のBicep ファイルをコピーし、ローカルに保存します。このファイルを使用して、検証エラー、プレフライトエラー、デプロイエラーのトラブルシューティングを行います。このクイックスタートでは、 troubleshoot.bicep ファイルに名前を付けたものの、任意の名前を付けることができることを前提としています。

@description('SKU for the storage account')
@allowed([
  'Standard_LRS'
  'Standard_GRS'
  'Standard_ZRS'
  'Premium_LRS'
])
parameter storageAccountType string = 'Standard_LRS'

@description('Prefix for storage name.')
param prefixName string

var storageAccountName = '${prefixName}${uniqueString(resourceGroup().id)}'

resource storageAccount 'Microsoft.Storage/storageAccounts@2021-06-01' = {
  name: storageAccountName
  location: resourceGroup().location
  sku: {
    name: storageAccountType
  }
  kind: 'StorageV2'
  properties: {}
}

resource existingVNet 'Microsoft.Network/virtualNetworks@2021-03-01' existing = {
  name: 'doesnotexist'
}

output storageAccountName string = storageAccountName
output vnetResult object = existingVNet

検証エラーを修正する

Visual Studio Codeでファイルを開きます。注意すると、Visual Studio Codeが構文エラーを認識していることに気づくでしょう。最初のパラメーター宣言は、エラーを示す赤い波線でマークされます。

Bicep ファイル内の構文エラーが赤い波線で強調表示された Visual Studio Code のスクリーンショット。

エラーでマークされた行は次のとおりです。

@allowed([
  'Standard_LRS'
  'Standard_GRS'
  'Standard_ZRS'
  'Premium_LRS'
])
parameter storageAccountType string = 'Standard_LRS'

parameterの上にマウスポインターを置くと、エラーメッセージが表示されます。

Bicepファイルの構文エラーにカーソルを合わせたときに、Visual Studio Codeに表示される詳細なエラーメッセージのスクリーンショット。

メッセージの状態: この宣言型は認識されません。パラメーター、変数、リソース、または出力宣言を指定します。 このファイルをデプロイしようとすると、デプロイコマンドから同じエラーメッセージが表示されます。

パラメーター宣言のドキュメントを見ると、キーワードが実際にparamことがわかります。その構文を変更すると、検証エラーは消えます。 @allowedデコレーターもエラーとしてマークされましたが、そのエラーはパラメーター宣言を変更することでも解決されます。デコレーターの後にパラメーター宣言が必要なため、デコレーターはエラーとしてマークされました。宣言が正しくない場合、この条件は当てはまらなかった。

その固定行は次の通りです。

param storageAccountType string = 'Standard_LRS'

プレフライトエラーを修正する

検証エラーを修正したので、次にファイルをデプロイします。ただし、プレフライトエラーを表示するには、不適切なパラメーター値を指定します。

Azure CLI
PowerShell

az group create --name troubleshootRG --location westus
az deployment group create \
  --resource-group troubleshootRG \
  --template-file troubleshoot.bicep \
  --parameters prefixName=longNamewith!!Charactersthatarenotallowed

New-AzResourceGroup -Name troubleshootRG -Location westus
New-AzResourceGroupDeployment `
  -ResourceGroupName troubleshootRG `
  -TemplateFile troubleshoot.bicep `
  -prefixName longNamewith!!Charactersthatarenotallowed

Azure Resource Managerは、ストレージアカウントの名前に許可されていない文字が含まれていることを決定します。デプロイは試されません。

プレフライト検証に失敗したことを示すエラーメッセージが表示されます。また、ストレージアカウント名の長さは 3 ~ 24 文字で、数字と小文字のみを使用する必要があるというメッセージも表示されます。指定したプレフィックスがその要件を満たしませんでした。このエラーコードの詳細については、「ストレージアカウント名のエラーを解決する」を参照してください。

エラーはプレフライトでキャッチされたため、履歴にデプロイは存在しません。

Azure ポータルの展開履歴セクションに、Bicep ファイルのデプロイメントがないことを示すスクリーンショット

ただし、失敗したデプロイはアクティビティログに存在します。

Azure ポータルのアクティビティログのスクリーンショットで、Bicep ファイルのデプロイメントに関するプリフライト検証エラーが表示されています。

ログエントリの詳細を開いて、エラーメッセージを表示できます。

デプロイエラーを修正する

ファイルをもう一度デプロイし、名前プレフィックスパラメーターに使用できる値を指定します。

Azure CLI
PowerShell

az group create --name troubleshootRG --location westus
az deployment group create \
  --resource-group troubleshootRG \
  --template-file troubleshoot.bicep \
  --parameters prefixName=stg

New-AzResourceGroup -Name troubleshootRG -Location westus
New-AzResourceGroupDeployment `
  -ResourceGroupName troubleshootRG `
  -TemplateFile troubleshoot.bicep `
  -prefixName stg

デプロイは開始されますが、仮想ネットワークが見つからなかったというメッセージで失敗します。通常は、リソースへの参照を変更することで、このエラーを修正します。このクイックスタートでは、参照を削除します。このエラーコードの詳細については、「リソースが見つからないエラーを解決する」を参照してください。

ポータルの履歴にデプロイが表示されていることに気づいてください。

Azure ポータルのデプロイ履歴セクションのスクリーンショットで、Bicep ファイルのデプロイ失敗を示しています。

デプロイ履歴のエントリを開いて、エラーの詳細を取得できます。このエラーはアクティビティログにも存在します。

Bicep ファイルは、リソースグループに存在しない仮想ネットワークを参照しようとします。既存の仮想ネットワークへの参照を削除して、エラーを修正します。

@description('SKU for the storage account')
@allowed([
  'Standard_LRS'
  'Standard_GRS'
  'Standard_ZRS'
  'Premium_LRS'
])
param storageAccountType string = 'Standard_LRS'

@description('Prefix for storage name.')
param prefixName string

var storageAccountName = '${prefixName}${uniqueString(resourceGroup().id)}'

resource storageAccount 'Microsoft.Storage/storageAccounts@2021-06-01' = {
  name: storageAccountName
  location: resourceGroup().location
  sku: {
    name: storageAccountType
  }
  kind: 'StorageV2'
  properties: {}
}

output storageAccountName string = storageAccountName

エラーを発生させずに、そのBicepファイルをデプロイできます。

リソースをクリーンアップする

Azure リソースが不要になったら、リソースグループを削除します。リソースグループは、Cloud Shellまたはポータルから削除できます。

Azure CLI
PowerShell

az group delete --name troubleshootRG

<rgname> を角括弧ごとリソースグループ名に置き換えます。

Remove-AzResourceGroup -Name troubleshootRG

ポータルでリソースグループを削除するには、このステップに従います。

Azure ポータルで、検索ボックスに「Resource groups」と入力します。
[ 名前でフィルター] フィールドに、リソースグループ名を入力します。
リソースグループ名を選択します。
[ リソースグループの削除] を選択します。
削除を確定するには、リソースグループ名を入力し、[ 削除] を選択します。

次のステップ

このクイックスタートでは、Bicep ファイルのデプロイエラーのトラブルシューティング方法について学びました。

一般的なAzureデプロイエラーをトラブルシューティングする

フィードバック

このページはお役に立ちましたか?

Last updated on 2025-05-02