Esercizio - Aggiungere parametri ed espressioni Decorator

Come parte della migrazione dell'applicazione HR, si sta creando un modello Bicep per la distribuzione di risorse di Azure. In questo esercizio si creeranno un piano di servizio app di Azure e un'app del servizio app. Si applicheranno espressioni Decorator a ogni parametro per assicurarsi che contengano sempre i valori previsti.

Durante il processo verranno eseguite le attività seguenti:

Questo esercizio usa l'estensione Bicep per Visual Studio Code. Assicurarsi di installare questa estensione in Visual Studio Code.

Creare un modello Bicep con parametri

1. Apri Visual Studio Code.

2. Creare un nuovo file denominato main.bicep.

3. Salvare il file vuoto in modo che Visual Studio Code possa caricare gli strumenti di Bicep.

   È possibile selezionare File>Salva con nome oppure selezionare Ctrl+S in Windows (⌘+S in macOS). Assicurarsi di ricordare dove è stato salvato il file. Ad esempio, è possibile creare una cartella scripts in cui salvarla.

4. Aggiungere nel file il contenuto riportato di seguito. Il modello verrà distribuito a breve. Immettere il contenuto manualmente anziché copiarlo e incollarlo, in modo da sperimentare in prima persona l'ausilio offerto dagli strumenti quando si scrivono file Bicep.

   param environmentName string = 'dev'
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   param appServicePlanInstanceCount int = 1
   param appServicePlanSku object = {
     name: 'F1'
     tier: 'Free'
   }
   param location string = 'eastus'
   
   var appServicePlanName = '${environmentName}-${solutionName}-plan'
   var appServiceAppName = '${environmentName}-${solutionName}-app'
   

   Si stanno creando svariati parametri che usano tipi diversi. Si stanno definendo i valori predefiniti per ogni parametro. Alcuni dei valori predefiniti includono l'interpolazione di stringhe e la funzione uniqueString().

   Suggerimento

   La funzione uniqueString() è utile per creare nomi di risorse univoci a livello globale. Restituisce una stringa che è la stessa in ogni distribuzione nello stesso gruppo di risorse, ma diversa quando si esegue la distribuzione in sottoscrizioni o gruppi di risorse diversi.

   Si stanno inoltre definendo variabili che costruiscono i nomi del piano di servizio app di Azure e dell'app del servizio app. I valori corrispondenti includono alcuni dei parametri specificati. L'utente che esegue la distribuzione può sostituire i valori dei parametri, ma non i valori delle variabili.

5. Nel file main.bicep in Visual Studio Code aggiungere il codice seguente alla fine del file:

   resource appServicePlan 'Microsoft.Web/serverfarms@2024-04-01' = {
     name: appServicePlanName
     location: location
     sku: {
       name: appServicePlanSku.name
       tier: appServicePlanSku.tier
       capacity: appServicePlanInstanceCount
     }
   }
   
   resource appServiceApp 'Microsoft.Web/sites@2024-04-01' = {
     name: appServiceAppName
     location: location
     properties: {
       serverFarmId: appServicePlan.id
       httpsOnly: true
     }
   }
   

   Si noti che le risorse usano i valori dei parametri che sono stati definiti.

6. Salvare le modifiche apportate al file.

Aggiungere descrizioni dei parametri

1. Nel file main.bicep in Visual Studio Code aggiungere l'espressione Decorator @description direttamente sopra ogni parametro creato nell'attività precedente. I parametri dovrebbero essere simili all'esempio seguente:

   @description('The name of the environment. This must be dev, test, or prod.')
   param environmentName string = 'dev'
   
   @description('The unique name of the solution. This is used to ensure that resource names are unique.')
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   
   @description('The number of App Service plan instances.')
   param appServicePlanInstanceCount int = 1
   
   @description('The name and tier of the App Service plan SKU.')
   param appServicePlanSku object = {
     name: 'F1'
     tier: 'Free'
   }
   
   @description('The Azure region into which the resources should be deployed.')
   param location string = 'eastus'
   

2. Salvare le modifiche apportate al file.

Limitare i valori di input

L’azienda di giocattoli distribuirà l'applicazione HR in tre ambienti: dev, test e prod. Il parametro environmentName verrà limitato solo per consentire tali tre valori.

1. Nel file main.bicep in Visual Studio Code individuare il parametro environmentName. Inserire un'espressione Decorator @allowed sotto la sua espressione Decorator @description. Al termine, il parametro dovrebbe essere simile all'esempio seguente:

   @description('The name of the environment. This must be dev, test, or prod.')
   @allowed([
     'dev'
     'test'
     'prod'
   ])
   param environmentName string = 'dev'
   

   Si noti che si sta limitando il valore del parametro environmentName solo a dev, test e prod. Se in futuro verranno aggiunti altri ambienti, sarà necessario aggiornare questo elenco.

2. Salvare le modifiche apportate al file.

Limitare le lunghezze di input

Il parametro solutionName viene usato per generare i nomi delle risorse. Si vuole imporre una lunghezza minima di 5 caratteri e una lunghezza massima di 30 caratteri.

1. Nel file main.bicep in Visual Studio Code individuare il parametro solutionName. Aggiungere le espressioni Decorator @minLength e @maxLength sotto l'espressione Decorator @description. Al termine, il parametro dovrebbe essere simile all'esempio seguente:

   @description('The unique name of the solution. This is used to ensure that resource names are unique.')
   @minLength(5)
   @maxLength(30)
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   

2. Salvare le modifiche apportate al file.

Limitare i valori numerici

Ora si verificherà che il parametro appServicePlanInstanceCount accetti solo valori compresi tra 1 e 10.

1. Nel file main.bicep in Visual Studio Code individuare il parametro appServicePlanInstanceCount. Aggiungere le espressioni Decorator @minValue e @maxValue sotto l'espressione Decorator @description. Al termine, il parametro dovrebbe essere simile all'esempio seguente:

   @description('The number of App Service plan instances.')
   @minValue(1)
   @maxValue(10)
   param appServicePlanInstanceCount int = 1
   

2. Salvare le modifiche apportate al file.

Verificare il file Bicep

Al termine di tutte le modifiche precedenti, il file Bicep avrà un aspetto simile al seguente:

@description('The name of the environment. This must be dev, test, or prod.')
@allowed([
  'dev'
  'test'
  'prod'
])
param environmentName string = 'dev'

@description('The unique name of the solution. This is used to ensure that resource names are unique.')
@minLength(5)
@maxLength(30)
param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'

@description('The number of App Service plan instances.')
@minValue(1)
@maxValue(10)
param appServicePlanInstanceCount int = 1

@description('The name and tier of the App Service plan SKU.')
param appServicePlanSku object = {
  name: 'F1'
  tier: 'Free'
}

@description('The Azure region into which the resources should be deployed.')
param location string = 'eastus'

var appServicePlanName = '${environmentName}-${solutionName}-plan'
var appServiceAppName = '${environmentName}-${solutionName}-app'

resource appServicePlan 'Microsoft.Web/serverfarms@2024-04-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: appServicePlanSku.name
    tier: appServicePlanSku.tier
    capacity: appServicePlanInstanceCount
  }
}

resource appServiceApp 'Microsoft.Web/sites@2024-04-01' = {
  name: appServiceAppName
  location: location
  properties: {
    serverFarmId: appServicePlan.id
    httpsOnly: true
  }
}

In caso contrario, copiare l'esempio oppure modificare il modello in modo che corrisponda all'esempio.

Distribuire il modello Bicep in Azure

az bicep install && az bicep upgrade

az deployment group create --name main --template-file main.bicep

New-AzResourceGroupDeployment -Name main -TemplateFile main.bicep

Verificare la distribuzione

1. Passare al portale di Azure e assicurarsi di entrare nella sottoscrizione corretta.

2. Nel pannello di sinistra selezionare Gruppi di risorse.

3. Selezionare il nome del gruppo di risorse.

4. In Panoramica viene visualizzata una distribuzione completata.

   

5. Selezionare 1 Operazione riuscita per visualizzare i dettagli della distribuzione.

   

6. Selezionare la distribuzione denominata main per visualizzare le risorse distribuite e quindi selezionare Dettagli della distribuzione per espanderla. In questo caso, sono presenti un piano di servizio app e un'app.

   

7. Selezionare Input nel menu a sinistra.

   

8. Notare che sono elencati i parametri e i relativi valori.

   

9. Lasciare aperta la pagina nel browser. Controllerai le distribuzioni di nuovo più tardi.