Exercice – ajouter des paramètres et des éléments décoratifs

Dans le cadre de la migration de l’application des ressources humaines, vous créez un modèle Bicep pour déployer des ressources Azure. Dans cet exercice, vous allez créer un plan Azure App Service et une application App Service. Vous appliquerez des éléments décoratifs à chaque paramètre pour vous assurer qu’ils comprennent toujours les valeurs attendues.

Au cours du processus, vous allez effectuer les tâches suivantes :

Cet exercice utilise l’extension Bicep pour Visual Studio Code. Assurez-vous d’installer cette extension dans Visual Studio Code.

Créer un modèle Bicep avec des paramètres

1. Ouvrez Visual Studio Code.

2. Créez un fichier appelé main.bicep.

3. Enregistrez le fichier vide afin que Visual Studio Code charge les outils Bicep.

   Vous pouvez soit sélectionner Fichier>Enregistrer sous, soit Ctrl+S dans Windows (⌘+S sur macOS). Veillez à mémoriser l’emplacement où vous avez enregistré le fichier. Vous pouvez par exemple créer un dossier scripts pour l’y enregistrer.

4. Ajoutez le contenu suivant au fichier. Vous allez bientôt déployer le modèle. Entrez ces informations vous-même au lieu d’effectuer un copier-coller afin de voir comment les outils vous aident à écrire vos fichiers Bicep.

   param environmentName string = 'dev'
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   param appServicePlanInstanceCount int = 1
   param appServicePlanSku object = {
     name: 'F1'
     tier: 'Free'
   }
   param location string = 'eastus'
   
   var appServicePlanName = '${environmentName}-${solutionName}-plan'
   var appServiceAppName = '${environmentName}-${solutionName}-app'
   

   Vous créez plusieurs paramètres ici qui utilisent différents types. Vous définissez des valeurs par défaut pour chaque paramètre. Certaines des valeurs par défaut incluent l’interpolation de chaîne et la fonction uniqueString().

   Conseil / Astuce

   La fonction uniqueString() est utile pour créer des noms de ressource globalement uniques. Elle retourne une chaîne identique sur chaque déploiement du même groupe de ressources, mais différente lors de déploiements sur des groupes de ressources ou des abonnements différents.

   Vous définissez également des variables qui construisent les noms du plan Azure App Service et de l’application App Service. Leurs valeurs incluent certains des paramètres que vous avez spécifiés. Les valeurs de paramètres peuvent être remplacées par l’utilisateur qui exécute le déploiement, mais les valeurs des variables ne peuvent pas être remplacées.

5. Dans le fichier main.bicep dans Visual Studio Code, ajoutez le code suivant au bas du fichier :

   resource appServicePlan 'Microsoft.Web/serverfarms@2024-04-01' = {
     name: appServicePlanName
     location: location
     sku: {
       name: appServicePlanSku.name
       tier: appServicePlanSku.tier
       capacity: appServicePlanInstanceCount
     }
   }
   
   resource appServiceApp 'Microsoft.Web/sites@2024-04-01' = {
     name: appServiceAppName
     location: location
     properties: {
       serverFarmId: appServicePlan.id
       httpsOnly: true
     }
   }
   

   Notez que les ressources utilisent les valeurs des paramètres que vous avez définis.

6. Enregistrez les modifications du fichier.

Ajouter des descriptions de paramètres

1. Dans le fichier main.bicep dans Visual Studio Code, ajoutez le @description décorateur directement au-dessus de chaque paramètre que vous avez créé dans la tâche précédente. Les paramètres doivent ressembler à cet exemple :

   @description('The name of the environment. This must be dev, test, or prod.')
   param environmentName string = 'dev'
   
   @description('The unique name of the solution. This is used to ensure that resource names are unique.')
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   
   @description('The number of App Service plan instances.')
   param appServicePlanInstanceCount int = 1
   
   @description('The name and tier of the App Service plan SKU.')
   param appServicePlanSku object = {
     name: 'F1'
     tier: 'Free'
   }
   
   @description('The Azure region into which the resources should be deployed.')
   param location string = 'eastus'
   

2. Enregistrez les modifications du fichier.

Limiter les valeurs d’entrée

Votre entreprise de jouets va déployer l’application RH dans trois environnements : dev, test et prod. Vous allez limiter le paramètre environmentName pour autoriser uniquement ces trois valeurs.

1. Dans le fichier main.bicep dans Visual Studio Code, recherchez le environmentName paramètre. Insérez un élément décoratif @allowed sous son élément décoratif @description. Une fois que vous avez terminé, le paramètre doit ressembler à cet exemple :

   @description('The name of the environment. This must be dev, test, or prod.')
   @allowed([
     'dev'
     'test'
     'prod'
   ])
   param environmentName string = 'dev'
   

   Notez que vous limitez la valeur de paramètre pour le paramètre environmentName à dev, test et prod uniquement. Si d’autres environnements sont ajoutés ultérieurement, vous devrez mettre à jour cette liste.

2. Enregistrez les modifications du fichier.

Limiter les longueurs d’entrée

Votre paramètre solutionName est utilisé pour générer les noms des ressources. Vous souhaitez appliquer une longueur minimale de 5 caractères et une longueur maximale de 30 caractères.

1. Dans le fichier main.bicep dans Visual Studio Code, recherchez le solutionName paramètre. Ajoutez les éléments décoratifs @minLength et @maxLength sous l’élément décoratif @description. Une fois que vous avez terminé, le paramètre doit ressembler à cet exemple :

   @description('The unique name of the solution. This is used to ensure that resource names are unique.')
   @minLength(5)
   @maxLength(30)
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   

2. Enregistrez les modifications du fichier.

Limiter les valeurs numériques

Vous allez ensuite vous assurer que le paramètre appServicePlanInstanceCount autorise uniquement des valeurs comprises entre 1 et 10.

1. Dans le fichier main.bicep dans Visual Studio Code, recherchez le appServicePlanInstanceCount paramètre. Ajoutez les éléments décoratifs @minValue et @maxValue sous l’élément décoratif @description. Une fois que vous avez terminé, le paramètre doit ressembler à cet exemple :

   @description('The number of App Service plan instances.')
   @minValue(1)
   @maxValue(10)
   param appServicePlanInstanceCount int = 1
   

2. Enregistrez les modifications du fichier.

Vérifier votre fichier Bicep

Une fois que vous avez effectué toutes les modifications précédentes, votre fichier Bicep doit ressembler à l’exemple suivant :

@description('The name of the environment. This must be dev, test, or prod.')
@allowed([
  'dev'
  'test'
  'prod'
])
param environmentName string = 'dev'

@description('The unique name of the solution. This is used to ensure that resource names are unique.')
@minLength(5)
@maxLength(30)
param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'

@description('The number of App Service plan instances.')
@minValue(1)
@maxValue(10)
param appServicePlanInstanceCount int = 1

@description('The name and tier of the App Service plan SKU.')
param appServicePlanSku object = {
  name: 'F1'
  tier: 'Free'
}

@description('The Azure region into which the resources should be deployed.')
param location string = 'eastus'

var appServicePlanName = '${environmentName}-${solutionName}-plan'
var appServiceAppName = '${environmentName}-${solutionName}-app'

resource appServicePlan 'Microsoft.Web/serverfarms@2024-04-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: appServicePlanSku.name
    tier: appServicePlanSku.tier
    capacity: appServicePlanInstanceCount
  }
}

resource appServiceApp 'Microsoft.Web/sites@2024-04-01' = {
  name: appServiceAppName
  location: location
  properties: {
    serverFarmId: appServicePlan.id
    httpsOnly: true
  }
}

Si ce n’est pas le cas, copiez l’exemple ou ajustez votre modèle pour qu’il corresponde à l’exemple.

Déployer le modèle Bicep sur Azure

az bicep install && az bicep upgrade

az deployment group create --name main --template-file main.bicep

New-AzResourceGroupDeployment -Name main -TemplateFile main.bicep

Vérifier votre déploiement

1. Accédez au portail Azure et vérifiez que vous êtes dans l’abonnement approprié.

2. Dans le volet gauche, sélectionnez Groupes de ressources.

3. Sélectionnez le nom de votre groupe de ressources.

4. Dans Vue d’ensemble, vous pouvez voir qu’un déploiement a réussi.

   

5. Sélectionnez 1 Réussite pour afficher les détails du déploiement.

   

6. Sélectionnez le déploiement appelé principal pour voir quelles ressources ont été déployées, puis sélectionnez Les détails du déploiement pour le développer. Dans ce cas, il existe un plan et une application App Service.

   

7. Dans le menu de gauche, sélectionnez Entrées.

   

8. Notez que les paramètres et leurs valeurs sont répertoriés.

   

9. Laissez la page ouverte dans votre navigateur. Vous allez à nouveau vérifier les déploiements plus tard.