Jaa

Table.TransformColumnTypes

Syntaksi

Table.TransformColumnTypes(
    table as table,
    typeTransformations as list,
    optional culture as nullable text
) as table

Noin

Palauttaa taulukon käyttämällä muunnostoimintoja määritetyissä sarakkeissa käyttämällä valinnaista maa-asetusta.

  • table: Muuntettava syötetaulukko.
  • typeTransformations: Käytettävät muunnokset. Yksittäisen muunnoksen muoto on { sarakkeen nimi, kirjoita arvo }. Muunnosten luettelon avulla voidaan muuttaa useamman kuin yhden sarakkeen tyyppejä kerrallaan. Jos saraketta ei ole, esiin tulee virhe.
  • culture: (Valinnainen) Saraketyyppien muuntamiseen käytettävä maa-asetus (esimerkiksi "en-US"). Jos -parametrille cultureon määritetty tietue, se voi sisältää seuraavat kentät:
    • Culture: Maa-asetus, jota käytetään muuntaessa saraketyyppejä (esimerkiksi "en-US").
    • MissingField: Jos saraketta ei ole, esiin tulee virhe, ellei tämä kenttä tarjoa vaihtoehtoista toimintaa (esimerkiksi MissingField.UseNull tai MissingField.Ignore).

typeTransformations-parametrin tyyppiarvo voi olla any, kaikki number -tyypit, text, kaikki date, time, datetime, datetimezoneja duration -tyypit, logicaltai binary. list-, record-, table- tai function-tyypit eivät ole kelvollisia tälle parametrille.

Kullekin kohteessa typeTransformationsluetellulle sarakkeelle on . Määritettyä tyyppiarvoa vastaavaa From-menetelmää käytetään yleensä muunnoksen suorittamiseen. Jos esimerkiksi Currency.Type sarakkeelle annetaan tyypin arvo, muunnosfunktiota Currency.From käytetään kaikkiin kyseisen sarakkeen arvoihin.

Esimerkki 1

Muunna ensimmäisen sarakkeen lukuarvot tekstiarvoksi.

käyttö

let
    Source = #table(type table [a = number, b = number],
    {
        {1, 2},
        {3, 4}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source,
        {"a", type text}
    )
in
    #"Transform Column"

Tuloste

#table(type table [a = text, b = number],
{
    {"1", 2},
    {"3", 4}
})

Esimerkki 2

Muunna taulukon päivämäärät ranskankielisinä tekstiekvivalentteina.

käyttö

let
    Source = #table(type table [Company ID = text, Country = text, Date = date],
    {
        {"JS-464", "USA", #date(2024, 3, 24)},
        {"LT-331", "France", #date(2024, 10, 5)},
        {"XE-100", "USA", #date(2024, 5, 21)},
        {"RT-430", "Germany", #date(2024, 1,18)},
        {"LS-005", "France", #date(2023, 12, 31)},
        {"UW-220", "Germany", #date(2024, 2, 25)}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source,
        {"Date", type text},
        "fr-FR"
    )
in
    #"Transform Column"

Tuloste

#table(type table [Company ID = text, Country = text, Date = text],
{
    {"JS-464", "USA", "24/03/2024"},
    {"LT-331", "France", "05/10/2024"},
    {"XE-100", "USA", "21/05/2024"},
    {"RT-430", "Germany", "18/01/2024"},
    {"LS-005", "France", "31/12/2023"},
    {"UW-220", "Germany", "25/02/2024"}
})

Esimerkki 3

Muunna taulukon päivämäärät saksalaiseksi tekstivastineen ja taulukon arvot prosenttiosuuksiksi.

käyttö

let
    Source = #table(type table [Date = date, Customer ID = text, Value = number],
    {
        {#date(2024, 3, 12), "134282", .24368},
        {#date(2024, 5, 30), "44343", .03556},
        {#date(2023, 12, 14), "22", .3834}
    }),
    #"Transform Columns" = Table.TransformColumnTypes(
        Source,
        {{"Date", type text}, {"Value", Percentage.Type}},
        "de-DE")
in
    #"Transform Columns"

Tuloste

#table(type table [Date = text, Customer ID = text, Value = Percentage.Type],
{
    {"12.03.2024", "134282", .24368},
    {"30.05.2024", "44343", .03556},
    {"14.12.2023", "22", .3834}
})

Esimerkki 4

Käytä muunnoksia tietuearvolla kohteelle culture.

käyttö

let
    Source = #table(type table [Company ID = text, Country = text, Date = date],
    {
        {"JS-464", "USA", #date(2024, 3, 24)},
        {"LT-331", "France", #date(2024, 10, 5)},
        {"XE-100", "USA", #date(2024, 5, 21)},
        {"RT-430", "Germany", #date(2024, 1,18)},
        {"LS-005", "France", #date(2023, 12, 31)},
        {"UW-220", "Germany", #date(2024, 2, 25)}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source,
        {{"Date", type text}, {"NewColumn", type number}},
        [Culture="fr-FR", MissingField=MissingField.UseNull]
    )
in
    #"Transform Column"

Tuloste

#table(type table [Company ID = text, Country = text, Date = text, NewColumn = number],
{
    {"JS-464", "USA", "24/03/2024", null},
    {"LT-331", "France", "05/10/2024", null},
    {"XE-100", "USA", "21/05/2024", null},
    {"RT-430", "Germany", "18/01/2024", null},
    {"LS-005", "France", "31/12/2023", null},
    {"UW-220", "Germany", "25/02/2024", null}
})

Aiheeseen liittyvä sisältö

  • Last updated on