Async.SwitchToContext (Método de F#)

Crea un cálculo asincrónico que ejecuta su continuación mediante el método Post del objeto de contexto de sincronización.

Espacio de nombres/Ruta de acceso del módulo: Microsoft.FSharp.Control

Ensamblado: FSharp.Core (en FSharp.Core.dll)

// Signature:
static member SwitchToContext : SynchronizationContext -> Async<unit>

// Usage:
Async.SwitchToContext (syncContext)

Parámetros

• syncContext
  Tipo: SynchronizationContext

  Contexto de sincronización que va a aceptar el cálculo expuesto.

Valor devuelto

Cálculo asincrónico que usa el contexto syncContext para su ejecución.

Comentarios

Si syncContext es NULL, el cálculo asincrónico es equivalente a Async.SwitchToThreadPool.

Ejemplo

En el ejemplo de código siguiente se muestra cómo usar Async.SwitchToContext para pasar al subproceso de la interfaz de usuario a fin de actualizar dicha interfaz. En este caso, se actualiza una barra de progreso que indica el estado de finalización de un cálculo.

open System.Windows.Forms

let form = new Form(Text = "Test Form", Width = 400, Height = 400)
let syncContext = System.Threading.SynchronizationContext.Current
let button1 = new Button(Text = "Start")
let label1 = new Label(Text = "", Height = 200, Width = 200,
                       Top = button1.Height + 10)
form.Controls.AddRange([| button1; label1 |] )

type invokeFunction = delegate of unit -> unit

let async1(syncContext, form : System.Windows.Forms.Form) =
    async {
        let label1 = form.Controls.[1]
        // Do something.
        do! Async.Sleep(1000)

        // Switch to the UI thread and update the UI.
        do! Async.SwitchToContext(syncContext)

        let threadNumber = System.Threading.Thread.CurrentThread.ManagedThreadId
        label1.Text <- label1.Text + sprintf "On the UI Thread [%d]\n" threadNumber

        // Switch back to the thread pool.
        do! Async.SwitchToThreadPool()
        // Do something.
        do! Async.Sleep(1000)

        let threadNumber = System.Threading.Thread.CurrentThread.ManagedThreadId

        // When on a thread pool thread, use Control.Invoke to update UI.
        label1.Invoke(new invokeFunction(fun () -> 
            label1.Text <- label1.Text +
                       sprintf "Switched to thread pool [%d]\n" threadNumber)) |> ignore
    }

let buttonClick(sender:obj, args) =
    let button = sender :?> Button
    Async.Start(async1(syncContext, button.Parent :?> Form))

    let threadNumber = System.Threading.Thread.CurrentThread.ManagedThreadId
    label1.Text <- sprintf "Started asynchronous workflow [%d]\n"  threadNumber
    ()

button1.Click.AddHandler(fun sender args -> buttonClick(sender, args))
Application.Run(form)

Plataformas

Windows 7, Windows Vista SP2, Windows XP SP3, Windows XP x64 SP2, Windows Server 2008 R2, Windows Server 2008 SP2, Windows Server 2003 SP2

Información de versiones

Runtime de F#

Se admite en las versiones: 2.0, 4.0

Silverlight

Se admite en la versión: 3

Vea también

Referencia

Control.Async (Clase de F#)

Microsoft.FSharp.Control (Espacio de nombres de F#)

Historial de cambios