Configure the connector for OPC UA

1. Select devices and then Create device:

   

   Tip

   Use the filter box to search for devices.

2. On the Basics page, enter a device name and select New on the Microsoft.OpcUa tile to add an endpoint for the device:

   

3. Enter your endpoint information. For example, to use the OPC PLC simulator, enter the following values:

   Field	Value
   Name	opc-ua-connector-0
   Connector for OPC UA URL	opc.tcp://opcplc-000000:50000
   User authentication	Anonymous

4. Select Next. On the Additional Info page enter any custom properties for the device.

5. Select Next to review your device details. Then select Create.

Run the following commands:

az iot ops ns device create \
  -n opc-ua-connector-cli \
  -g {your resource group name} \
  --instance {your instance name}

az iot ops ns device endpoint inbound add opcua \
  --device opc-ua-connector-cli \
  -g {your resource group name} \
  -i {your instance name} \
  --name opc-ua-connector-0 \
  --endpoint-address "opc.tcp://opcplc-000000:50000"

To learn more, see az iot ops ns device.

Deploy the following Bicep template to create a device with an inbound endpoint for the OPC UA connector. Replace the placeholders <AIO_NAMESPACE_NAME> and <CUSTOM_LOCATION_NAME> with your Azure IoT Operations namespace name and custom location name respectively:

param aioNamespaceName string = '<AIO_NAMESPACE_NAME>'
param customLocationName string = '<CUSTOM_LOCATION_NAME>'

resource namespace 'Microsoft.DeviceRegistry/namespaces@2025-10-01' existing = {
  name: aioNamespaceName
}

resource customLocation 'Microsoft.ExtendedLocation/customLocations@2021-08-31-preview' existing = {
  name: customLocationName
}

resource device 'Microsoft.DeviceRegistry/namespaces/devices@2025-10-01' = {
  name: 'opc-ua-connector-bicep'
  parent: namespace
  location: resourceGroup().location
  extendedLocation: {
    type: 'CustomLocation'
    name: customLocation.id
  }
  properties: {
    endpoints: {
      outbound: {
        assigned: {}
      }
      inbound: {
        'opc-ua-connector-0': {
          endpointType: 'Microsoft.OpcUa'
          address: 'opc.tcp://opcplc-000000:50000'
          authentication: {
            method: 'Anonymous'
          }
        }
      }
    }
  }
}

Follow the steps in Manage secrets for your Azure IoT Operations deployment to add secrets for username and password in Azure Key Vault, project them into Kubernetes cluster, and reference them from your device configuration.

1. Follow the steps in Manage secrets for your Azure IoT Operations deployment to add secrets for username and password in Azure Key Vault, and project them into Kubernetes cluster.

2. Use the az iot ops ns device endpoint inbound add command with the --user-ref and --pass-ref parameters to add the references to the Azure Key Vault secrets you created.

1. Follow the steps in Manage secrets for your Azure IoT Operations deployment to add secrets for username and password in Azure Key Vault, and project them into Kubernetes cluster.

2. Modify the authentication block of your Bicep configuration for the connector to reference the synchronized secrets for username and password, as shown in the example below:

   authentication: {
       method: 'UsernamePassword'
           usernamePasswordCredentials: {
               passwordSecretName: '<reference to synced password secret>'
               usernameSecretName: '<reference to synced username secret>'
           }
   }
   

To add an asset in the operations experience, follow these steps:

1. Select the Assets tab. Before you create any assets, you see the following screen:

   

   Tip

   Use the filter box to search for assets.

2. Select Create asset.

3. On the asset details screen, enter the following asset information:

   • Inbound endpoint. Select your device inbound endpoint from the list.
   • Asset name
   • Description

4. Configure the set of custom properties that you want to associate with the asset. You can accept the default list of properties or add your own. The following properties are available by default:

   • Manufacturer
   • Manufacturer URI
   • Model
   • Product code
   • Hardware version
   • Software version
   • Serial number
   • Documentation URI

   

5. Select Next to go to the Datasets page.

Add a dataset to an asset

A dataset defines where the connector sends the data it collects from a collection of data points. An OPC UA asset can have multiple datasets. To create a dataset:

1. Select Create dataset.

2. Enter the details for the dataset such as its name and destination. For OPC UA assets, the destination is an MQTT topic. For example:

   

   Use the Start instance field to specify the starting node for resolving relative browse paths for data points in the dataset. For more information, see Resolve nodes dynamically using browse paths.

3. Select Create and next to create the dataset.

Add individual data points to a dataset

Now you can define the data points associated with the dataset. To add OPC UA data points:

1. Select Add data point.

2. Enter your data point details:

   • Data source. This value is the node ID from the OPC UA server.
   • Data point name (Optional). This value is the friendly name that you want to use for the data point. If you don't specify a data point name, the node ID is used as the data point name.
   • Sampling interval (milliseconds). You can override the default value for this data point.
   • Queue size. You can override the default value for this data point.

   

   The following table shows some example data point values that you can use with the built-in OPC PLC simulator:

   Data source	Data point name
   ns=3;s=FastUInt10	Temperature
   ns=3;s=FastUInt100	Humidity

   Note

   If you're using relative browse paths to resolve dynamic nodes, the Data source field contains a relative browse path. For more information, see Resolve nodes dynamically using browse paths.

3. On the data points page, select Next to go to the Add events page.

Use the following commands to add a thermostat asset to your device by using the Azure CLI. The commands add a dataset and two data points to the asset by using the point add command:

# Create the asset
az iot ops ns asset opcua create \
  --name thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --device opc-ua-connector-cli \
  --endpoint opc-ua-connector-0 \
  --description 'A simulated thermostat asset'

# Add the dataset
az iot ops ns asset opcua dataset add \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --name oven \
  --data-source "" \
  --dest topic="azure-iot-operations/data/thermostat" retain=Never qos=Qos1 ttl=3600

# Add the data points
az iot ops ns asset opcua datapoint add \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --dataset oven \
  --name temperature \
  --data-source "ns=3;s=FastUInt10"

az iot ops ns asset opcua datapoint add \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --dataset oven \
  --name humidity \
  --data-source "ns=3;s=FastUInt100"

# Show the dataset and datapoints
az iot ops ns asset opcua dataset show \
  --asset thermostat \
  -n oven \
  -g {your resource group name} \
  --instance {your instance name}

When you create an asset by using the Azure CLI, you can define:

• Multiple data points by using the point add command multiple times.
• Multiple events by using the --event parameter multiple times.
• Optional information for the asset such as:
  • Manufacturer
  • Manufacturer URI
  • Model
  • Product code
  • Hardware version
  • Software version
  • Serial number
  • Documentation URI
• Default values for sampling interval, publishing interval, and queue size.
• Datapoint specific values for sampling interval, publishing interval, and queue size.
• Event specific values for sampling publishing interval, and queue size.
• The observability mode for each data point and event

Deploy the following Bicep template to create an asset that publishes messages from the device shown previously to an MQTT topic. Replace the placeholders <AIO_NAMESPACE_NAME> and <CUSTOM_LOCATION_NAME> with your Azure IoT Operations namespace name and custom location name respectively:

param aioNamespaceName string = '<AIO_NAMESPACE_NAME>'
param customLocationName string = '<CUSTOM_LOCATION_NAME>'

resource namespace 'Microsoft.DeviceRegistry/namespaces@2025-10-01' existing = {
  name: aioNamespaceName
}

resource customLocation 'Microsoft.ExtendedLocation/customLocations@2021-08-31-preview' existing = {
  name: customLocationName
}

resource asset 'Microsoft.DeviceRegistry/namespaces/assets@2025-10-01' = {
  name: 'thermostat'
  parent: namespace
  location: resourceGroup().location
  extendedLocation: {
    type: 'CustomLocation'
    name: customLocation.id
  }
  properties: {
    displayName: 'thermostat'
    description: 'A simulated thermostat asset'
    enabled: true

    deviceRef: {
      deviceName: 'opc-ua-connector-bicep'
      endpointName: 'opc-ua-connector-0'
    }

    defaultDatasetsConfiguration: '{}'
    defaultEventsConfiguration: '{}'

    datasets: [
      {
        name: 'oven'
        datasetConfiguration: '{}'
        dataPoints: [
          {
            name: 'temperature'
            dataSource: 'ns=3;s=FastUInt10'
            dataPointConfiguration: '{}'
          }
          {
            name: 'humidity'
            dataSource: 'ns=3;s=FastUInt100'
            dataPointConfiguration: '{}'
          }
        ]
        destinations: [
          {
            target: 'Mqtt'
            configuration: {
              topic: 'azure-iot-operations/data/thermostat'
              qos: 'Qos1'
              retain: 'Never'
              ttl: 3600
            }
          }
        ]
      }
    ]
  }
}

Add an event group to an asset

An event group defines where the connector sends the data it receives from a collection of events. An OPC UA asset can have multiple event groups. To create an event group:

1. Select Create event group.

2. Enter a name for the event group and any other required details:

   

3. Select Create and next to create the event group and go to the List of events for alerts page.

Add events to an event group

Now you can define the events associated with the event group. To add OPC UA events:

1. Select Add event.

2. Enter your event details:

   • Data source. This value is the event notifier from the OPC UA server.
   • Event name (Optional). This value is the friendly name that you want to use for the event. If you don't specify an event name, the event notifier is used as the event name.
   • Topic. The MQTT topic that you want the event to be published to.
   • Sampling interval (milliseconds). You can override the default value for this data point.
   • Queue size. You can override the default value for this data point.
   • Start instance. This value is the starting node for resolving relative browse paths for this event. This field is required if you use relative browse paths in the Data source field. For more information, see Resolve nodes dynamically using browse paths.
   • Event filter. An optional configuration that defines the event filter for this event. For more information, see the Event filters section.

   

3. Select Manage default settings to configure default event settings for the asset. These settings apply to all the OPC UA events that belong to the asset. You can override these settings for each event that you add. Default event settings include:

   • Publishing interval (milliseconds): The rate at which OPC UA server should publish data.
   • Queue size: The depth of the queue to hold the sampling data before publishing it.

To add an event group and events to an existing asset, use the az iot ops ns asset opcua event-group and az iot ops ns asset custom event commands:

# Add an event group to the thermostat asset
az iot ops ns asset opcua event-group add \
  --data-source "" \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --name alerts

# Add an event to the event group
az iot ops ns asset custom event add \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --event-group alerts \
  --name serverObjectNotifier \
  --data-source "ns=0;i=2253" \
  --dest topic="azure-iot-operations/events/test-thermostat-cli" retain=Never qos=Qos1 ttl=3600

# List the event groups for the asset
az iot ops ns asset opcua event-group list \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name}

When you add an event group by using the Azure CLI, you can configure:

• Event group name and data source
• Publishing interval and queue size
• Event destinations (MQTT topic, QoS, retain, TTL)

To add individual events to an event group, use the az iot ops ns asset custom event add command with the --event-group parameter.

To remove an event group, use the az iot ops ns asset opcua event-group remove command.

To add events and event groups to an asset by using Bicep, include the eventGroups array in the asset properties. Each event group can contain an events array with individual events:

eventGroups: [
  {
    name: 'alerts'
    eventGroupConfiguration: '{"publishingInterval":1000,"queueSize":10}'
    events: [
      {
        name: 'serverObjectNotifier'
        dataSource: 'ns=0;i=2253'
        eventConfiguration: '{}'
        destinations: [
          {
            target: 'Mqtt'
            configuration: {
              topic: 'azure-iot-operations/events/test-thermostat-bicep'
              qos: 'Qos1'
              retain: 'Never'
              ttl: 3600
            }
          }
        ]
      }
    ]
  }
]

The eventGroupConfiguration property is a stringified JSON object that can include connector-specific settings such as publishingInterval and queueSize. Individual events use the eventConfiguration property for event-specific settings including per-event destinations.

The following screenshot shows an example event filter:

The following command updates an existing event definition to include an event filter by using the config parameter:

az iot ops ns asset custom event add \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --event-group alerts \
  --name serverObjectNotifier \
  --data-source "ns=0;i=2253" \
  --dest topic="azure-iot-operations/events/test-thermostat-cli" retain=Never qos=Qos1 ttl=3600 \
  --replace true \
  --config "{\"eventFilter\":{\"selectClauses\":[{\"browsePath\":\"EventId\",\"typeDefinitionId\":\"ns=0;i=2041\",\"fieldId\":\"myEventId\"},{\"browsePath\":\"EventType\",\"typeDefinitionId\":\"ns=0;i=2041\",\"fieldId\":\"EventType\"},{\"browsePath\":\"SourceName\",\"typeDefinitionId\":\"\",\"fieldId\":\"mySourceName\"},{\"browsePath\":\"Severity\",\"typeDefinitionId\":\"\",\"fieldId\":\"Severity\"}]}}"

To configure event filters by using Bicep, include the filter configuration in the eventConfiguration property of individual events within an event group:

eventGroups: [
  {
    name: 'alerts'
    eventGroupConfiguration: '{"publishingInterval":1000,"queueSize":10}'
    events: [
      {
        name: 'serverObjectNotifier'
        dataSource: 'ns=0;i=2253'
        eventConfiguration: '{"eventFilter":{"selectClauses":[{"browsePath":"EventId","typeDefinitionId":"ns=0;i=2041","fieldId":"myEventId"},{"browsePath":"EventType","typeDefinitionId":"ns=0;i=2041","fieldId":"EventType"},{"browsePath":"SourceName","typeDefinitionId":"","fieldId":"mySourceName"},{"browsePath":"Severity","typeDefinitionId":"","fieldId":"Severity"}]}}'
        destinations: [
          {
            target: 'Mqtt'
            configuration: {
              topic: 'azure-iot-operations/events/test-thermostat-bicep'
              qos: 'Qos1'
              retain: 'Never'
              ttl: 3600
            }
          }
        ]
      }
    ]
  }
]

The selectClauses array defines which fields to include in the event notification and optionally renames them using the alias property.

Review your asset and OPC UA data point and event details. Make any adjustments you need:

To review your asset configuration, use the following commands:

# View the complete asset details
az iot ops ns asset show \
  --name thermostat \
  --instance {your instance name} \
  -g {your resource group name}

# List datasets and data points
az iot ops ns asset opcua dataset list \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name}

# List event groups
az iot ops ns asset opcua event-group list \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name}

To review your Bicep template before deployment, use the what-if operation:

az deployment group what-if --resource-group {your resource group name} --template-file asset.bicep

This command shows you what changes would be made to your Azure resources without actually deploying them.

Find and select the asset you created previously. Use the Asset details, data points, and Events tabs to make any changes:

On the view data points tab for a dataset, you can add data points, update existing data points, or remove data points.

To update a data point, select an existing data point and update the data point information. Then select Update:

To remove data points, select one or more data points and then select Remove data points:

You can also add, update, and delete events and properties in the same way.

When you're finished making changes, select Save to save your changes.

To list your assets associated with a specific endpoint, use the following command:

az iot ops ns asset query \
  --device {your device name} \
  --endpoint {your endpoint name} \
  -g {your resource group name} \
  --instance {your instance name}

To view the details of the thermostat asset, use the following command:

az iot ops ns asset show \
  --name thermostat \
  --instance {your instance name} \
  -g {your resource group}

To update an asset, use the az iot ops ns asset opcua update command. For example, to update the asset's description, use a command like the following example:

az iot ops ns asset opcua update \
  --name thermostat \
  --instance {your instance name} \
  -g {your resource group} \
  --description "Updated factory PLC"

To list the thermostat asset's data points in a dataset, use the following command:

az iot ops ns asset opcua dataset show \
  --asset thermostat \
  --name oven \
  -g {your resource group} \
  --instance {your instance name}

To list the thermostat asset's event groups, use the following command:

az iot ops ns asset opcua event-group list \
  --asset thermostat \
  -g {your resource group} \
  --instance {your instance name}

To add a new data point to the thermostat asset, use a command like the following example:

az iot ops ns asset opcua datapoint add \
  --asset thermostat \
  --instance {your instance name} \
  -g {your resource group name} \
  --dataset oven \
  --name humidity \
  --data-source "ns=3;s=FastUInt100"

To delete a data point, use the az iot ops ns asset opcua dataset point remove command.

You can manage an asset's event groups by using the az iot ops ns asset opcua event-group commands.

To retrieve an asset by using Bicep, use a template like the following example:

param aioNamespaceName string = '<AIO_NAMESPACE_NAME>'

resource namespace 'Microsoft.DeviceRegistry/namespaces@2025-10-01' existing = {
  name: aioNamespaceName
}

resource asset 'Microsoft.DeviceRegistry/namespaces/assets@2025-10-01' existing = {
  name: 'thermostat'
  parent: namespace
}

output asset object = asset

To update an existing asset, for example to modify the description and add a data point, use a template like the following example:

param aioNamespaceName string = '<AIO_NAMESPACE_NAME>'
param customLocationName string = '<CUSTOM_LOCATION_NAME>'

resource namespace 'Microsoft.DeviceRegistry/namespaces@2025-10-01' existing = {
  name: aioNamespaceName
}

resource customLocation 'Microsoft.ExtendedLocation/customLocations@2021-08-31-preview' existing = {
  name: customLocationName
}

resource asset 'Microsoft.DeviceRegistry/namespaces/assets@2025-10-01' = {
  name: 'thermostat'
  parent: namespace
  location: resourceGroup().location
  extendedLocation: {
    type: 'CustomLocation'
    name: customLocation.id
  }
  properties: {
    displayName: 'thermostat'
    description: 'Updated thermostat asset with voltage data point'
    enabled: true

    deviceRef: {
      deviceName: 'opc-ua-connector-bicep'
      endpointName: 'opc-ua-connector-0'
    }

    defaultDatasetsConfiguration: '{}'
    defaultEventsConfiguration: '{}'

    datasets: [
      {
        name: 'oven'
        datasetConfiguration: '{}'
        dataPoints: [
          {
            name: 'temperature'
            dataSource: 'ns=3;s=FastUInt10'
            dataPointConfiguration: '{}'
          }
          {
            name: 'humidity'
            dataSource: 'ns=3;s=FastUInt100'
            dataPointConfiguration: '{}'
          }
          {
            name: 'voltage'
            dataSource: 'ns=3;s=FastUInt101'
            dataPointConfiguration: '{}'
          }
        ]
        destinations: [
          {
            target: 'Mqtt'
            configuration: {
              topic: 'azure-iot-operations/data/thermostat'
              qos: 'Qos1'
              retain: 'Never'
              ttl: 3600
            }
          }
        ]
      }
    ]
  }
}

To delete an asset, select the asset you want to delete. On the Asset details page, select Delete. Confirm your changes to delete the asset:

To delete an asset, use a command that looks like the following example:

az iot ops ns asset delete \
  --name thermostat \
  -g {your resource group name} \
  --instance {your instance name}

To delete individual resources by using Bicep, see Deployment stacks.