Async.SwitchToContext-Methode (F#)

Erstellt eine asynchrone Berechnung, die die Fortsetzung mit der Post-Methode für das Synchronisierungskontextobjekt ausführt.

Namespace/Modulpfad: Microsoft.FSharp.Control

Assembly: FSharp.Core (in FSharp.Core.dll)

// Signature:
static member SwitchToContext : SynchronizationContext -> Async<unit>

// Usage:
Async.SwitchToContext (syncContext)

Parameter

• syncContext
  Typ: SynchronizationContext

  Der Synchronisierungskontext, in dem die bereitgestellte Berechnung akzeptiert wird.

Rückgabewert

Eine asynchrone Berechnung, die den auszuführenden syncContext-Kontext verwendet.

Hinweise

Wenn syncContext NULL ist, entspricht die asynchrone Berechnung Async.SwitchToThreadPool.

Beispiel

Im folgenden Codebeispiel wird veranschaulicht, wie mit Async.SwitchToContext zum UI-Thread gewechselt wird, um die Benutzeroberfläche zu aktualisieren. In diesem Fall wird eine Statusanzeige aktualisiert, die den Abschlusszustand einer Berechnung angibt.

open System.Windows.Forms

let form = new Form(Text = "Test Form", Width = 400, Height = 400)
let syncContext = System.Threading.SynchronizationContext.Current
let button1 = new Button(Text = "Start")
let label1 = new Label(Text = "", Height = 200, Width = 200,
                       Top = button1.Height + 10)
form.Controls.AddRange([| button1; label1 |] )

type invokeFunction = delegate of unit -> unit

let async1(syncContext, form : System.Windows.Forms.Form) =
    async {
        let label1 = form.Controls.[1]
        // Do something.
        do! Async.Sleep(1000)

        // Switch to the UI thread and update the UI.
        do! Async.SwitchToContext(syncContext)

        let threadNumber = System.Threading.Thread.CurrentThread.ManagedThreadId
        label1.Text <- label1.Text + sprintf "On the UI Thread [%d]\n" threadNumber

        // Switch back to the thread pool.
        do! Async.SwitchToThreadPool()
        // Do something.
        do! Async.Sleep(1000)

        let threadNumber = System.Threading.Thread.CurrentThread.ManagedThreadId

        // When on a thread pool thread, use Control.Invoke to update UI.
        label1.Invoke(new invokeFunction(fun () -> 
            label1.Text <- label1.Text +
                       sprintf "Switched to thread pool [%d]\n" threadNumber)) |> ignore
    }

let buttonClick(sender:obj, args) =
    let button = sender :?> Button
    Async.Start(async1(syncContext, button.Parent :?> Form))

    let threadNumber = System.Threading.Thread.CurrentThread.ManagedThreadId
    label1.Text <- sprintf "Started asynchronous workflow [%d]\n"  threadNumber
    ()

button1.Click.AddHandler(fun sender args -> buttonClick(sender, args))
Application.Run(form)

Plattformen

Windows 7, Windows Vista SP2, Windows XP SP3, Windows XP x64 SP2, Windows Server 2008 R2, Windows Server 2008 SP2, Windows Server 2003 SP2

Versionsinformationen

F#-Runtime

Unterstützt in: 2.0, 4.0

Silverlight

Unterstützt in: 3

Siehe auch

Weitere Ressourcen

Control.Async-Klasse (F#)

Microsoft.FSharp.Control-Namespace (F#)

Änderungsprotokoll