LineSlant-Eigenschaft

Gibt an, auf welche Weise sich eine Linie neigt: von links oben nach rechts unten oder von links unten nach rechts oben. Diese Eigenschaft ist zur Entwurfs- und Laufzeit verfügbar.

Line.LineSlant[ = cSlant]

Eigenschaftswerte

• cSlant
  Die folgenden Einstellungen für die LineSlant-Eigenschaft sind möglich:

  Einstellung	Beschreibung
  \	(Standardeinstellung) Linie neigt sich von links oben nach rechts unten.
  /	Linie neigt sich von links unten nach rechts oben.

Beispiel

Das folgende Beispiel zeigt, wie die LineSlant-Eigenschaft zur Angabe der Neigungsrichtung eines Linien-Steuerelements verwendet wird.

Ein Linien-Steuerelement wird dem Formular hinzugefügt. Drei Befehlsschaltflächen werden zum Formular hinzugefügt. Diese ermöglichen es, die Neigungsrichtung der Linien zu ändern oder das Formular zu schließen.

frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .F.  && Disable the Control menu box 

frmMyForm.AddObject('shpLine','Line')  && Add a Line control to the form
frmMyForm.AddObject('cmdCmndBtn1','cmdMyCmndBtn1')  && Up Cmnd button
frmMyForm.AddObject('cmdCmndBtn2','cmdMyCmndBtn2')  && Down Cmnd button
frmMyForm.AddObject('cmdCmndBtn3','cmdMyCmndBtn3')  && Quit Cmnd button

frmMyForm.shpLine.Visible = .T.  && Make Line control visible
frmMyForm.shpLine.Top = 20  && Specify Line control row
frmMyForm.shpLine.Left = 125  && Specify Line control column

frmMyForm.cmdCmndBtn1.Visible =.T.  && Up Command button visible
frmMyForm.cmdCmndBtn2.Visible =.T.  && Down" Command button visible
frmMyForm.cmdCmndBtn3.Visible =.T.  && Quit Command button visible

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS cmdMyCmndBtn1 AS COMMANDBUTTON  && Create Command button
   Caption = 'Slant \<Up'  && Caption on the Command button
   Left = 50  && Command button column
   Top = 100  && Command button row
   Height = 25  && Command button height
   
   PROCEDURE Click
      ThisForm.shpLine.Visible = .F.  && Hide the Line control
      ThisForm.shpLine.LineSlant ='/'  && Slant up
      ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn2 AS CommandButton  && Create Command button
   Caption = 'Slant \<Down'  && Caption on the Command button
   Left = 200  && Command button column
   Top = 100  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      ThisForm.shpLine.Visible = .F.  && Hide the Line control
      ThisForm.shpLine.LineSlant ='\'  && Slant down
      ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn3 AS CommandButton  && Create Command button
   Caption = '\<Quit'  && Caption on the Command button
   Cancel = .T.  && Default Cancel Command button (Esc)
   Left = 125  && Command button column
   Top = 150  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      CLEAR EVENTS  && Stop event processing, close Form
ENDDEFINE

Siehe auch

DrawMode-Eigenschaft | DrawStyle-Eigenschaft

Betrifft: Linien-Steuerelement (Line)