Closable-Eigenschaft

Gibt an, ob das Formular durch einen Doppelklick auf das Popup-Menüsymbol des Fensters, durch Auswahl von Schließen im Popup-Menü des Fensters oder durch Klicken auf die Schaltfläche Schließen geschlossen werden kann. Diese Eigenschaft ist zur Entwurfs- und Laufzeit verfügbar.

Object.Closable[ = lExpr]

Eigenschaftswerte

• lExpr
  Für die Closable-Eigenschaft gibt es die folgenden Einstellungsmöglichkeiten:

  Einstellung	Beschreibung
  Wahr (.T.)	(Standardwert) Der Eintrag Schließen wird dem Popup-Menü des Fensters hinzugefügt.
  Falsch (.F.)	Das Formular lässt sich nicht durch Doppelklicken auf das Popup-Menüsymbol des Fensters schließen und der Menübefehl Schließen ist aus dem Popup-Menü entfernt worden.

Beispiel

Im folgenden Beispiel wird die Closable-Eigenschaft auf Falsch (.F.) festgelegt, um zu verhindern, dass ein Formular mit Hilfe des Popup-Menüs des Fensters oder der Schaltfläche Schließen geschlossen werden kann. Ist dagegen die Closable-Eigenschaft eines Formulars auf Wahr (.T.) festgelegt und wird das Formular mit Hilfe des Popup-Menüs des Fensters geschlossen, muss zum Beenden der Ereignisverarbeitung und Verlassen des Programms CLEAR EVENTS aufgerufen werden.

frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .F.  && Disable the window pop-up menu
                          && and Close button

frmMyForm.AddObject('shpLine','Line')  && Add a Line control to the form
frmMyForm.AddObject('cmdCmndBtn1','cmdMyCmndBtn1')  && Up Cmnd button
frmMyForm.AddObject('cmdCmndBtn2','cmdMyCmndBtn2')  && Down Cmnd button
frmMyForm.AddObject('cmdCmndBtn3','cmdMyCmndBtn3')  && Quit Cmnd button

frmMyForm.shpLine.Visible = .T.  && Make Line control visible
frmMyForm.shpLine.Top = 20  && Specify Line control row
frmMyForm.shpLine.Left = 125  && Specify Line control column

frmMyForm.cmdCmndBtn1.Visible =.T.  && Up Command button visible
frmMyForm.cmdCmndBtn2.Visible =.T.  && Down" Command button visible
frmMyForm.cmdCmndBtn3.Visible =.T.  && Quit Command button visible

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS cmdMyCmndBtn1 AS COMMANDBUTTON  && Create Command button
   Caption = 'Slant \<Up'  && Caption on the Command button
   Left = 50  && Command button column
   Top = 100  && Command button row
   Height = 25  && Command button height
   
   PROCEDURE Click
      ThisForm.shpLine.Visible = .F.  && Hide the Line control
      ThisForm.shpLine.LineSlant ='/'  && Slant up
      ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn2 AS CommandButton  && Create Command button
   Caption = 'Slant \<Down'  && Caption on the Command button
   Left = 200  && Command button column
   Top = 100  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      ThisForm.shpLine.Visible = .F.  && Hide the Line control
      ThisForm.shpLine.LineSlant ='\'  && Slant down
      ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn3 AS CommandButton  && Create Command button
   Caption = '\<Quit'  && Caption on the Command button
   Cancel = .T.  && Default Cancel Command button (Esc)
   Left = 125  && Command button column
   Top = 150  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      CLEAR EVENTS  && Stop event processing, close Form
ENDDEFINE

Siehe auch

ControlBox-Eigenschaft | TitleBar-Eigenschaft | DEFINE CLASS | QueryUnload-Ereignis | Unload-Ereignis | Release-Methode | Destroy-Ereignis

Betrifft: Formularobjekt (Form) | _SCREEN-Systemvariable