Cancel-Eigenschaft

Gibt an, ob es sich bei einer Befehlsschaltfläche oder einem OLE-Container-Steuerelement um die Schaltfläche Abbrechen handelt. Ist dem so, wird beim Drücken von ESC das Click-Ereignis des Steuerelements aufgerufen. Diese Eigenschaft ist zur Entwurfs- und Laufzeit verfügbar.

Object.Cancel[ = lExpr]

Eigenschaftswerte

• lExpr
  Die Einstellungen für die Cancel-Eigenschaft lauten:

  Einstellung	Beschreibung
  Wahr (.T.)	Bei der Befehlsschaltfläche bzw. dem OLE-Container-Steuerelement handelt es sich um die Schaltfläche Abbrechen.
  Falsch (.F.)	(Standard) Bei der Befehlsschaltfläche bzw. dem OLE-Container-Steuerelement handelt es sich nicht um die Schaltfläche Abbrechen.

Hinweise

Die Cancel-Eigenschaft ist nur auf OLE-Container-Steuerelemente anwendbar, die ein ActiveX-Steuerelement (OCX) enthalten, das sich wie eine Schaltfläche verhält.

Beispiel

Im folgenden Beispiel wird eine Befehlsschaltfläche und ein Optionsgruppen-Steuerelement (OptionGroup) erstellt und auf einem Formular angeordnet. Mit Hilfe der Cancel-Eigenschaft wird diese Befehlsschaltfläche als Schaltfläche Abbrechen deklariert. Wird ESC gedrückt, so tritt das Click-Ereignis der Befehlsschaltfläche ein. Dessen Prozedur führt CLEAR EVENTS aus, so dass das Formular geschlossen und die Ereignisverarbeitung beendet wird.

Die Optionsgruppe verfügt über drei Optionsfelder; je nach angeklicktem Feld wird ein Kreis, eine Ellipse oder ein Quadrat angezeigt. Mit Hilfe des Form-Steuerelements (Shape) werden Kreis, Ellipse und Quadrat erstellt. Das Click-Ereignis des Optionsgruppen-Steuerelements (OptionGroup) verwendet eine DO CASE ... ENDCASE-Befehlsstruktur und die Value-Eigenschaft, um beim Klicken auf eine Optionsschaltfläche die entsprechende Form anzuzeigen,

frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .F.  && Disable the Control menu box 

frmMyForm.AddObject('cmdCommand1','cmdMyCmndBtn')  && Add Command button
frmMyForm.AddObject('opgOptionGroup1','opgMyOptGrp') && Add Option Group
frmMyForm.AddObject('shpCircle1','shpMyCircle')  && Add Circle Shape
frmMyForm.AddObject('shpEllipse1','shpMyEllipse')  && Add Ellipse Shape
frmMyForm.AddObject('shpSquare','shpMySquare')  && Add Box Shape

frmMyForm.cmdCommand1.Visible =.T.  && "Quit" Command button visible

frmMyForm.opgOptionGroup1.Buttons(1).Caption = "\<Circle"
frmMyForm.opgOptionGroup1.Buttons(2).Caption = "\<Ellipse"
frmMyForm.opgOptionGroup1.Buttons(3).Caption = "\<Square"
frmMyForm.opgOptionGroup1.SetAll("Width", 100) && Set Option group width
frmMyForm.opgOptionGroup1.Visible = .T.  && Option Group visible
frmMyForm.opgOptionGroup1.Click  && Show the circle

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS opgMyOptGrp AS OptionGroup  && Create an Option Group
   ButtonCount = 3  && Three Option buttons
   Top = 10
   Left = 10
   Height = 75
   Width = 100

   PROCEDURE Click 
      ThisForm.shpCircle1.Visible = .F.  && Hide the circle
      ThisForm.shpEllipse1.Visible = .F.  && Hide the ellipse
      ThisForm.shpSquare.Visible = .F.  && Hide the square
      
      DO CASE
         CASE ThisForm.opgOptionGroup1.Value = 1
            ThisForm.shpCircle1.Visible = .T. && Show the circle
         CASE ThisForm.opgOptionGroup1.Value = 2 
            ThisForm.shpEllipse1.Visible = .T.  && Show the ellipse
         CASE ThisForm.opgOptionGroup1.Value = 3 
            ThisForm.shpSquare.Visible = .T.  && Show the square
      ENDCASE
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn AS CommandButton  && Create Command button
   Caption = '\<Quit'  && Caption on the Command button
   Cancel = .T.  && Default Cancel Command button (Esc)
   Left = 125  && Command button column
   Top = 210  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      CLEAR EVENTS  && Stop event processing, close Form
ENDDEFINE

DEFINE CLASS shpMyCircle AS SHAPE  && Create a circle
   Top = 10
   Left = 200
   Width = 100
   Height = 100
   Curvature = 99
   BackColor = RGB(255,0,0)  && Red
ENDDEFINE

DEFINE CLASS shpMyEllipse AS SHAPE  && Create an ellipse
   Top = 35
   Left = 200
   Width = 100
   Height = 50
   Curvature = 99
   BackColor = RGB(0,128,0)  && Green
ENDDEFINE

DEFINE CLASS shpMySquare AS SHAPE  && Create a square
   Top = 10
   Left = 200
   Width = 100
   Height = 100
   Curvature = 0
   BackColor = RGB(0,0,255)  && Blue
ENDDEFINE

Siehe auch

Click-Ereignis | Default-Eigenschaft | CANCEL-Befehl | Abbrechen-Schaltfläche

Betrifft: Befehlsschaltfläche-Steuerelement | OLE-Container-Steuerelement