Top-Eigenschaft

Gibt den Abstand zwischen dem obersten Rand eines Steuerelements oder einem Formular und seinem Container-Objekt an. Diese Eigenschaft ist zur Entwurfs- und zur Laufzeit verfügbar.

Object.Top[ = nValue]

Eigenschaftswerte

  • nValue
    Gibt den Abstand zwischen dem obersten Rand eines Objekts oder einem Formular und dem obersten Rand seines Container-Objekts an.

    Der Standardcontainer eines Formulars ist das Visual FoxPro-Hauptfenster.

Hinweise

Die Top-Eigenschaft gibt an, wie weit das Objekt von der Nullposition des Objekts entfernt ist. Wenn beispielsweise ein Formular im Visual FoxPro-Hauptfenster enthalten ist, liegt die Nullposition unmittelbar unterhalb des Systemmenüs, oder wenn eine Symbolleiste an dem oberen Rand des Hauptfensters angedockt ist, unmittelbar unter der Symbolleiste.

Verwenden Sie Left-, Top-, Height- und Width-Eigenschaften für Operationen, die auf den externen Abmessungen eines Objekts beruhen, wie Verschieben oder Ändern der Größe.

Anmerkung   Die Top-Eigenschaft ist schreibgeschützt, wenn sie auf ein Steuerelement in einem Spaltenobjekt angewendet wird.

Die von der Top-Eigenschaft verwendete Maßeinheit wird durch die Einstellung der ScaleMode-Eigenschaft des Steuerelements bestimmt.

Beispiel

Das folgende Beispiel zeigt, wie die Top-Eigenschaft verwendet wird, um die Steuerelemente eines Formulars zu positionieren. Mit der AddObject-Methode werden einem Formular ein Linien-Steuerelement und drei Befehlsschaltflächen hinzugefügt. Die Top-Eigenschaft gibt die vertikale Platzierung jedes Steuerelements in dem Formular an.

frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .F.  && Disable the window pop-up menu

frmMyForm.AddObject('shpLine','Line')  && Add a Line control to the form
frmMyForm.AddObject('cmdCmndBtn1','cmdMyCmndBtn1')  && Up Cmnd button
frmMyForm.AddObject('cmdCmndBtn2','cmdMyCmndBtn2')  && Down Cmnd button
frmMyForm.AddObject('cmdCmndBtn3','cmdMyCmndBtn3')  && Quit Cmnd button

frmMyForm.shpLine.Visible = .T.  && Make Line control visible
frmMyForm.shpLine.Top = 20  && Specify Line control row
frmMyForm.shpLine.Left = 125  && Specify Line control column

frmMyForm.cmdCmndBtn1.Visible =.T.  && Up Command button visible
frmMyForm.cmdCmndBtn2.Visible =.T.  && Down" Command button visible
frmMyForm.cmdCmndBtn3.Visible =.T.  && Quit Command button visible

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS cmdMyCmndBtn1 AS COMMANDBUTTON  && Create Command button
   Caption = 'Slant \<Up'  && Caption on the Command button
   Left = 50  && Command button column
   Top = 100  && Command button row
   Height = 25  && Command button height
   
   PROCEDURE Click
      ThisForm.shpLine.Visible = .F.  && Hide the Line control
      ThisForm.shpLine.LineSlant ='/'  && Slant up
      ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn2 AS CommandButton  && Create Command button
   Caption = 'Slant \<Down'  && Caption on the Command button
   Left = 200  && Command button column
   Top = 100  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      ThisForm.shpLine.Visible = .F.  && Hide the Line control
      ThisForm.shpLine.LineSlant ='\'  && Slant down
      ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn3 AS CommandButton  && Create Command button
   Caption = '\<Quit'  && Caption on the Command button
   Cancel = .T.  && Default Cancel Command button (Esc)
   Left = 125  && Command button column
   Top = 150  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      CLEAR EVENTS  && Stop event processing, close Form
ENDDEFINE

Siehe auch

Left-Eigenschaft | Height-Eigenschaft | Move-Methode | ScaleMode-Eigenschaft | Width-Eigenschaft

Betrifft: Kontrollkästchen-Steuerelement (CheckBox) | Kombinationsfeld-Steuerelement (ComboBox) | Befehlsschaltflächen-Steuerelement (CommandButton) | Schaltflächengruppe-Steuerelement (CommandGroup) | Container-Objekt | Control-Objekt | Custom-Objekt | Bearbeitungsfeld-Steuerelement (EditBox) | Formularobjekt (Form) | Datenraster-Steuerelement (Grid) | Bild-Steuerelement (Image) | Bezeichnungs-Steuerelement (Label) | Linien-Steuerelement (Linie) | Listenfeld-Steuerelement (ListBox) | Gebundenes OLE-Steuerelement | OLE-Container-Steuerelement | Optionsfeld-Steuerelement (OptionButton) | Optionsgruppen-Steuerelement (OptionGroup) | Seitenrahmen-Steuerelement (PageFrame) | _SCREEN-Systemvariable | Form-Steuerelement (Shape) | Drehfeld-Steuerelement (Spinner) | Textfeld-Steuerelement (TextBox) | Zeitgeber-Steuerelement (Timer) | Symbolleisten-Objekt

  • Last updated on