DynamicBackColor-, DynamicForeColor-Eigenschaften

Gibt die Hintergrund- bzw. die Vordergrundfarbe eines Spaltenobjekts an. Die Farben werden zur Laufzeit jedes Mal neu ausgewertet, wenn das Datenraster-Steuerelement (Grid) aktualisiert wird. Diese Eigenschaft ist zur Entwurfszeit verfügbar und hat zur Laufzeit Schreib-/Lesestatus.

Column.DynamicBackColor[ = cExpression]Column.DynamicForeColor
[ = cExpression]

Eigenschaftswerte

• cExpression
  Gibt einen Ausdruck in Anführungszeichen an, der zur Laufzeit erneut ausgewertet wird, wenn das Datenraster-Steuerelement (Grid) aktualisiert wird. Die Auswertung zur Laufzeit muss einen einzelnen Farbwert ergeben.

Hinweise

Sie können mit der DynamicBackColor- und der DynamicForeColor-Eigenschaft Spezialeffekte erzielen, also z. B. die Zeilen mit ungeraden Nummern grün und die Zeilen mit geraden Nummern grau anzeigen.

Beispiel

Das folgende Beispiel verwendet die DynamicBackColor-Eigenschaft und die SetAll-Methode, um die Hintergrundfarben für die Datensätze in einem Datenraster-Steuerelement (Grid) festzulegen. Ist die Nummer eines im Datenraster angezeigten Datensatzes gerade, ist die DynamicBackColor-Eigenschaft weiß; andernfalls ist sie grün.

Ein Datenraster-Steuerelement (Grid) wird in ein Formular eingefügt, und die Tabelle customer, deren Inhalt im Datenraster angezeigt wird, wird geöffnet. Mit der Caption-Eigenschaft wird eine andere Spaltenkopfbeschriftung (Kunden-ID) für das Feld CUST_ID festgelegt. Zum Schließen des Formulars wird eine Befehlsschaltfläche auf dem Formular eingefügt.

CLOSE ALL  && Close tables and databases
OPEN DATABASE (HOME(2) + 'Data\testdata')

USE customer  IN 0  && Opens Customer table

frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .f.  && Disable the Control menu box 

frmMyForm.AddObject('cmdCommand1','cmdMyCmdBtn')  && Add Command button
frmMyForm.AddObject('grdGrid1','Grid')  && Add Grid control

frmMyForm.grdGrid1.Left = 25  && Adjust Grid position

frmMyForm.grdGrid1.SetAll("DynamicBackColor", ;
   "IIF(MOD(RECNO( ), 2)=0, RGB(255,255,255) ;
   , RGB(0,255,0))", "Column")  && Alternate white and green records

frmMyForm.grdGrid1.Visible = .T.  && Grid control visible
frmMyForm.cmdCommand1.Visible =.T.  && "Quit" Command button visible
frmMyForm.grdGrid1.Column1.Header1.Caption = 'Customer ID'

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS cmdMyCmdBtn AS CommandButton  && Create Command button
   Caption = '\<Quit'  && Caption on the Command button
   Cancel = .T.  && Default Cancel Command button (Esc)
   Left = 125  && Command button column
   Top = 210  && Command button row
   Height = 25  && Command button height

   PROCEDURE Click
      CLEAR EVENTS  && Stop event processing, close Form
      CLOSE ALL  && Close table and database
ENDDEFINE

Siehe auch

BackColor, ForeColor-Eigenschaften

Betrifft: Column-Objekt