Einteilen von Objekten in untergeordnete Klassen

Sie können benutzerdefinierte Objekte erstellen, indem Sie auf Basis der mit Visual FoxPro gelieferten Basisklassen eigene Unterklassen bilden. Beispielsweise bildet der folgende Code eine Unterklasse auf der Basis des mit Visual FoxPro gelieferten Hierarchie-Steuerelements:

Bilden einer Unterklasse für das Hierarchie-Steuerelement

Code Kommentar 
PUBLIC frmMyForm, cFilename
SET SAFETY OFF
 Deklariert und initialisiert Variablen. 
frmMyForm = CREATEOBJECT("form")
frmMyForm.Width = 100
frmMyForm.ADDOBJECT("oleOutl","myoutline")
DIMENSION aSection(3)
aSection(1) = "Table"
aSection(2) = "Field"
aSection(3) = "Index"
 Erstellt ein Formular, fügt das benutzerdefinierte Hierarchie-Steuerelement zum Formular hinzu und erstellt anschließend ein Array für die im Steuerelement aufgeführten Elemente. 
cFilename = GETFILE("dbc","Select a DBC")
USE (cFilename)
INDEX ON objecttype FOR (objecttype = "Table" ;
   OR objecttype = "Field" ;
   OR objecttype = "Index" ) ;
   TAG fname
 Fordert zur Angabe der Datenbank auf, die die Informationen erhält, die vom Steuerelement aufgelistet werden sollen. 
FOR nIndex = 1 TO 3 STEP 1
   frmMyForm.oleOutl.AddItem(aSection(nIndex))
   frmMyForm.oleOutl.Indent;
    ((frmMyForm.oleOutl.ListCount-1)) = 1
   SCAN
      IF objecttype = aSection(nIndex)
         frmMyForm.oleOutl.Additem(objectname)
         frmMyForm.oleOutl.Indent;
         ((frmMyForm.oleOutl.ListCount-1)) = 2
      ENDIF
   ENDSCAN
   GO TOP
ENDFOR
 Trägt Informationen aus der Datenbank zusammen und fügt diese dann zum Steuerelement hinzu. 
frmMyForm.oleOutl.Visible = .T.
frmMyForm.Show
 Macht das Steuerelement sichtbar und zeigt anschließend das Formular an. 
DEFINE CLASS myoutline AS olecontrol
   OleClass = "msoutl.outline"
   Top = 5
   Left = 5
   Height = 10
   Width = 60
ENDDEFINE
 Definiert eine Unterklasse des OLE-Container-Steuerelements und fügt das Hierarchie-Steuerelement hinzu, indem die OleClass-Eigenschaft des Containers festgelegt wird und anschließend die anderen benutzerdefinierten Einstellungen angegeben werden.

Wenn Sie Ihre Anwendungen verteilen möchten, sind einige zusätzliche Aspekte zu beachten.

Siehe auch

Bearbeitung von Objekten mit Automatisierung | Steuern von Visual FoxPro über andere Anwendungen | Freigeben von Informationen und Hinzufügen von OLE | Verwenden von Remoteautomatisierung | Verwenden von ActiveX-Steuerelementen

  • Last updated on