Freigeben über

INFORMATIONEN. BEZIEHUNGEN

Gilt für: Berechnete Spalte Berechnete Tabelle Measure Visuelle Berechnung DAX Abfrage

Gibt eine Tabelle mit Informationen zu jeder Beziehung im Semantikmodell zurück. Diese Funktion stellt Metadaten zu Beziehungen zwischen Tabellen bereit.

Syntax

INFO.RELATIONSHIPS ( [<Restriction name>, <Restriction value>], ... )

Die Parameter

Parameter sind für diese DAX Funktion optional. Wenn Parameter verwendet werden, müssen beide angegeben werden. Es sind mehrere Parameterpaare zulässig. Der Einschränkungsname und -wert sind Text und werden in doppelte Anführungszeichen eingegeben.

Begriff Definition
Einschränkungsname Name der Einschränkung, die zum Filtern der Ergebnisse verwendet wird.
Einschränkungswert Wert, der zum Filtern der Ergebnisse der Einschränkung verwendet wird.

Einschränkungen

In der Regel können alle Spalten der DAX Funktionsergebnisse als Einschränkung verwendet werden. Weitere Einschränkungen können ebenfalls zulässig sein.

Rückgabewert

Eine Tabelle, deren Spalten dem Schema-Rowset für Beziehungen im aktuellen Semantikmodell entsprechen.

Kolumne Description
ID Eindeutiger Bezeichner für die Beziehung
ModelID Fremdschlüssel für das Modell, das diese Beziehung enthält
Name Name der Beziehung
IsActive Boolescher Wert, der angibt, ob die Beziehung aktiv ist
Typ Beziehungstyp (z. B. OneToMany, ManyToOne)
CrossFilteringBehavior (Verhalten bei Kreuzfilterung) Kreuzfilterverhalten (z. B. OneDirection, BothDirections)
JoinOnDateBehavior Verhalten für datumsbasierte Verknüpfungen
SetzeAufReferentielleIntegrität Boolescher Wert, der angibt, ob die referenzielle Integrität verwendet werden soll
FromTableID Fremdschlüssel zur Quelltabelle in der Beziehung
FromColumnID Fremdschlüssel zur Quellspalte in der Beziehung
FromCardinality Kardinalität auf der "Von"-Seite der Beziehung
ToTableID Fremdschlüssel zur Zieltabelle in der Beziehung
ToColumnID Fremdschlüssel zur Zielspalte in der Beziehung
ToCardinality Kardinalität auf der "zu"-Seite der Beziehung
Staat Aktueller Status der Beziehung
RelationshipStorageID Fremdschlüssel für die Speicherinformationen für Beziehungen
RelationshipStorage2ID Fremdschlüssel für Sekundärbeziehungsspeicherinformationen
ModifiedTime Datum und Uhrzeit der letzten Änderung der Beziehung
RefreshedTime Datum und Uhrzeit der letzten Aktualisierung der Beziehung
Sicherheitsfilterverhalten Sicherheitsfilterverhalten für die Beziehung

Bemerkungen

  • Wird in der Regel in DAX Abfragen verwendet, um Metadaten des Dokumentmodells zu prüfen und zu dokumentieren.
  • Erforderliche Berechtigungen hängen vom Host ab. Das Abfragen vollständiger Metadaten erfordert möglicherweise Modelladministratorberechtigungen.

Example

Die folgende DAX Abfrage kann in DAX Abfrageansichtausgeführt werden:

EVALUATE
	INFO.RELATIONSHIPS()

Beispiel 2 – DAX Abfrage mit Verknüpfungen

Die folgende DAX Abfrage kann in DAX Abfrageansichtausgeführt werden:

EVALUATE
VAR _Relationships = 
    SELECTCOLUMNS(
        INFO.RELATIONSHIPS(),
        "Relationship Name", [Name],
        "Is Active", [IsActive],
        "Type", [Type],
        "Cross Filtering", [CrossFilteringBehavior],
        "From Table ID", [FromTableID],
        "From Column ID", [FromColumnID],
        "To Table ID", [ToTableID],
        "To Column ID", [ToColumnID]
    )

VAR _FromTables = 
    SELECTCOLUMNS(
        INFO.TABLES(),
        "FromTableID", [ID],
        "From Table Name", [Name]
    )

VAR _ToTables = 
    SELECTCOLUMNS(
        INFO.TABLES(),
        "ToTableID", [ID],
        "To Table Name", [Name]
    )

VAR _FromColumns = 
    SELECTCOLUMNS(
        INFO.COLUMNS(),
        "FromColumnID", [ID],
        "From Column Name", [Name]
    )

VAR _ToColumns = 
    SELECTCOLUMNS(
        INFO.COLUMNS(),
        "ToColumnID", [ID],
        "To Column Name", [Name]
    )

VAR _CombinedTable1 = 
    NATURALLEFTOUTERJOIN(
        _Relationships,
        _FromTables
    )

VAR _CombinedTable2 = 
    NATURALLEFTOUTERJOIN(
        _CombinedTable1,
        _ToTables
    )

VAR _CombinedTable3 = 
    NATURALLEFTOUTERJOIN(
        _CombinedTable2,
        _FromColumns
    )

VAR _CombinedTable4 = 
    NATURALLEFTOUTERJOIN(
        _CombinedTable3,
        _ToColumns
    )

RETURN
    SELECTCOLUMNS(
        _CombinedTable4,
        "Relationship Name", [Relationship Name],
        "From Table", [From Table Name],
        "From Column", [From Column Name],
        "To Table", [To Table Name],
        "To Column", [To Column Name],
        "Is Active", [Is Active],
        "Type", [Type],
        "Cross Filtering", [Cross Filtering]
    )
ORDER BY [Relationship Name]

Siehe auch

  • Last updated on