Bewährte Methoden für FinOps für Web

In diesem Artikel wird eine Sammlung bewährter FinOps-Praktiken für Webdienste beschrieben. Es bietet Strategien zum Optimieren von Kosten, zur Verbesserung der Effizienz und zur Verwendung von Azure Resource Graph (ARG)-Abfragen, um Einblicke in Ihre Webressourcen zu erhalten. Durch die Einhaltung dieser Methoden können Sie sicherstellen, dass Ihre Webdienste kosteneffizient sind und den finanziellen Zielen Ihrer Organisation entsprechen.

App-Dienst

In den folgenden Abschnitten werden ARG-Abfragen für App Service bereitgestellt. Diese Abfragen helfen Ihnen, Einblicke in Ihre App Service-Ressourcen zu gewinnen und sicherzustellen, dass sie mit den entsprechenden Einstellungen konfiguriert sind. Indem Sie App Service-Pläne analysieren und Empfehlungen von Azure Advisor anzeigen, können Sie Ihre App Service-Ressourcen auf Kosteneffizienz optimieren.

Abfrage: Webanwendungsstatus

Diese ARG-Abfrage ruft den Status und grundlegende Informationen von Webanwendungen in Ihrer Azure-Umgebung ab.

Kategorie

Überwachung

Abfrage

resources
| where type =~ 'Microsoft.Web/sites'
| project
    id,
    WebAppName = name,
    Type = kind,
    Status = tostring(properties.state),
    WebAppLocation = location,
    AppServicePlan = tostring(properties.serverFarmId),
    WebAppRG = resourceGroup,
    SubscriptionId = subscriptionId
| order by id asc

Leere App Service-Pläne entfernen

Empfehlung: Entfernen Sie App Service-Pläne ohne gehostete Apps oder Funktionen, um unnötige Gebühren zu vermeiden.

Informationen zu leeren App Service-Plänen

App Service-Pläne definieren die Computeressourcen für Ihre Web-Apps. Kostenpflichtige Pläne verursachen Gebühren basierend auf ihrer konfigurierten SKU- und Instanzanzahl, unabhängig davon, ob apps auf ihnen gehostet werden. Leere Pläne können sich während der Entwicklung ansammeln oder wenn Apps zwischen Plänen verschoben werden. Durch das Entfernen nicht verwendeter Pläne werden unnötige Kosten beseitigt.

Identifizieren leerer App Service-Pläne

Verwenden Sie die folgende ARG-Abfrage, um App Service-Pläne ohne gehostete Apps zu identifizieren.

resources
| where type =~ 'microsoft.web/serverfarms'
| where toint(properties.numberOfSites) == 0
| where sku.tier !~ 'Free'
| project
    ResourceId = tolower(id),
    ResourceName = name,
    SKUName = tostring(sku.name),
    SKUTier = tostring(sku.tier),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

Abfrage: Details des App Service-Plans

Diese ARG-Abfrage ruft detaillierte Informationen zu Azure-App Serviceplänen in Ihrer Azure-Umgebung ab.

Kategorie

Ressourcenverwaltung

Abfrage

resources
| where type == "microsoft.web/serverfarms"  and sku.tier !~ 'Free'
| project
    planId = tolower(tostring(id)),
    name,
    skuname = tostring(sku.name),
    skutier = tostring(sku.tier),
    workers = tostring(properties.numberOfWorkers),
    maxworkers = tostring(properties.maximumNumberOfWorkers),
    webRG = resourceGroup,
    Sites = tostring(properties.numberOfSites),
    SubscriptionId = subscriptionId
| join kind=leftouter (
    resources
    | where type == "microsoft.insights/autoscalesettings"
    | project
        planId = tolower(tostring(properties.targetResourceUri)),
        PredictiveAutoscale = properties.predictiveAutoscalePolicy.scaleMode,
        AutoScaleProfiles = properties.profiles,
        resourceGroup
) on planId

Feedback senden

Lassen Sie uns mit einer kurzen Bewertung wissen, wie wir abschneiden. Wir verwenden diese Rezensionen, um FinOps-Tools und -Ressourcen zu verbessern und zu erweitern.

Wenn Sie nach etwas Spezifischem suchen, wählen Sie eine vorhandene Idee aus, oder erstellen Sie eine neue Idee. Teilen Sie Ideen mit anderen, um mehr Stimmen zu erhalten. Wir konzentrieren uns auf Ideen mit den meisten Stimmen.

Zugehöriger Inhalt

Verwandte Ressourcen:

• FinOps Framework

Verwandte Lösungen:

• FinOps-Toolkit Power BI-Berichte
• FinOps-Hubs
• FinOps-Arbeitsmappen
• Optimierungsmodul