Bewährte Praktiken für FinOps im Bereich Speicherverwaltung

In diesem Artikel wird eine Sammlung bewährter FinOps-Methoden für Speicherdienste beschrieben. Es bietet Strategien zum Optimieren von Kosten, zur Verbesserung der Effizienz und zur Verwendung von Azure Resource Graph (ARG)-Abfragen, um Einblicke in Ihre Speicherressourcen zu erhalten. Indem Sie diese Methoden ausführen, können Sie sicherstellen, dass Ihre Speicherdienste kosteneffizient sind und den finanziellen Zielen Ihrer Organisation entsprechen.

Datensicherung

In den folgenden Abschnitten werden ARG-Abfragen für Sicherungsdienste bereitgestellt. Diese Abfragen helfen Ihnen, Einblicke in Ihre Sicherungsressourcen zu erhalten und sicherzustellen, dass sie mit den entsprechenden Einstellungen konfiguriert sind. Durch die Analyse von Sicherungselementen und das Identifizieren von Leerlaufsicherungen können Sie Ihre Sicherungsdienste auf Kosteneffizienz optimieren.

Abfrage: Inaktiver Backups

Diese ARG-Abfrage analysiert Sicherungselemente in Azure Recovery Services Vaults und identifiziert alle, die seit über 90 Tagen nicht gesichert wurden.

Kategorie

Optimierung

Abfrage

recoveryservicesresources
| where type =~ 'microsoft.recoveryservices/vaults/backupfabrics/protectioncontainers/protecteditems'
| extend vaultId = tostring(properties.vaultId)
| extend resourceId = tostring(properties.sourceResourceId)
| extend idleBackup= datetime_diff('day', now(), todatetime(properties.lastBackupTime)) > 90
| extend  resourceType=tostring(properties.workloadType)
| extend protectionState=tostring(properties.protectionState)
| extend lastBackupTime=tostring(properties.lastBackupTime)
| extend resourceGroup=strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup)
| extend lastBackupDate=todatetime(properties.lastBackupTime)
| where idleBackup != 0
| project resourceId,vaultId,idleBackup,lastBackupDate,resourceType,protectionState,lastBackupTime,location,resourceGroup,subscriptionId

Abfrage: Liste der Wiederherstellungsdienst-Tresore

Diese AZURE Resource Graph (ARG)-Abfrage ruft Details von Azure Recovery Services Vaults ab. Die Abfrage enthält auch Informationen zur SKU-Ebene, Redundanzeinstellungen und anderen relevanten Metadaten.

Kategorie

Optimierung

Abfrage

resources
| where type == 'microsoft.recoveryservices/vaults'
| where resourceGroup in ({ResourceGroup})
| extend skuTier = tostring(sku['tier'])
| extend skuName = tostring(sku['name'])
| extend resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| extend redundancySettings = tostring(properties.redundancySettings['standardTierStorageRedundancy'])
| order by id asc
| project id, redundancySettings, resourceGroup, location, subscriptionId, skuTier, skuName

Datenträger

Azure verwaltete Datenträger sind Speichervolumes auf Blockebene, die von Azure verwaltet und mit virtuellen Computern verwendet werden. Verwaltete Datenträger bieten hohe Verfügbarkeit, Skalierbarkeit und Sicherheit für Ihre VM-Workloads.

Verwandte Ressourcen:

• Verwaltete Datenträger – Preise
• Dokumentation zu verwalteten Datenträgern

Nicht angefügte Datenträger entfernen

Empfehlung: Nicht angefügte verwaltete Datenträger entfernen oder herabstufen, um unnötige Speicherkosten zu vermeiden.

Informationen zu nicht angehängten Datenträgern

Wenn ein virtueller Computer gelöscht wird, werden die zugeordneten verwalteten Datenträger möglicherweise nicht automatisch gelöscht. Diese nicht angefügten (verwaisten) Datenträger verursachen weiterhin Speicherkosten basierend auf ihrem Datenträgertyp und ihrer Größe. Die Abfrage schließt Datenträger aus, die sich im aktiven SAS-Übertragungsmodus befinden oder Azure Site Recovery-Replikat- oder -Seed-Datenträger sind, da diese voraussichtlich vorübergehend nicht eingebunden sind.

Identifizieren von nicht angefügten Datenträgern

Verwenden Sie die folgende ARG-Abfrage, um nicht angefügte verwaltete Datenträger zu identifizieren.

resources
| where type =~ 'microsoft.compute/disks' and managedBy == ""
| extend diskState = tostring(properties.diskState)
| where managedBy == ""
    and diskState != 'ActiveSAS'
    and tags !contains 'ASR-ReplicaDisk'
    and tags !contains 'asrseeddisk'
| extend DiskId=id, DiskIDfull=id, DiskName=name, SKUName=sku.name, SKUTier=sku.tier, DiskSizeGB=tostring(properties.diskSizeGB), Location=location, TimeCreated=tostring(properties.timeCreated), SubId=subscriptionId
| order by DiskId asc
| project DiskId, DiskIDfull, DiskName, DiskSizeGB, SKUName, SKUTier, resourceGroup, Location, TimeCreated, subscriptionId

Abfrage: Disk-Snapshot älter als 30 Tage

Diese ARG-Abfrage identifiziert Momentaufnahmen von Datenträgern, die älter als 30 Tage sind.

Kategorie

Optimierung

Abfrage

resources
| where type == 'microsoft.compute/snapshots'
| extend TimeCreated = properties.timeCreated
| extend resourceGroup = strcat("/subscriptions/",subscriptionId,"/resourceGroups/",resourceGroup)
| where TimeCreated < ago(30d)
| order by id asc 
| project id, resourceGroup, location, TimeCreated, subscriptionId

Premium-Snapshots herabstufen

Empfehlung: Verwenden Sie für Momentaufnahmen verwalteter Datenträger Standard-Speicher anstelle von Premium-Speicher, um die Speicherkosten zu senken.

Informationen zu Premium-Momentaufnahmen

Verwaltete Datenträgermomentaufnahmen, die auf Premium-Speicher gespeichert sind, verursachen höhere Kosten als Standardspeicher. In den meisten Fällen erfordern Momentaufnahmen nicht die Leistung des Premium-Speichers, da sie für Sicherung und Wiederherstellung verwendet werden, nicht aktive E/A. Die Herabstufung auf den Standardspeicher kann die Snapshot-Kosten erheblich reduzieren, ohne dass sich dies auf ihre Funktionalität auswirkt.

Premium-Snapshots identifizieren

Verwenden Sie die folgende ARG-Abfrage, um Momentaufnahmen verwalteter Datenträger mit Premium-Speicher zu identifizieren.

resources
| where type == 'microsoft.compute/snapshots'
| extend
    StorageSku = tostring(sku.tier),
    resourceGroup = strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup),
    diskSize = tostring(properties.diskSizeGB)
| where StorageSku == "Premium"
| project id, name, StorageSku, diskSize, location, resourceGroup, subscriptionId

Speicherkonten

Azure Storage Konten stellen einen eindeutigen Namespace in Azure für Ihre Daten bereit. Speicherkonten haben sich durch mehrere Generationen weiterentwickelt, und die Verwendung von Legacy-Kontotypen kann den Zugriff auf neuere Features und Optimierungen einschränken.

Verwandte Ressourcen:

• Produktseite des Speicherkontos
• Preisgestaltung für Speicherkonten
• Dokumentation zu Speicherkonten

Upgrade von Legacyspeicherkonten

Empfehlung: Führen Sie für Speicherkonten vom Typ GPv1 oder BlobStorage ein Upgrade auf GPv2 durch, um von besseren Preisstufen, zusätzlichen Funktionen und fortlaufendem Support zu profitieren.

Informationen zu veralteten Speicherkonten

Speicherkonten, die die GPv1- oder BlobStorage-Art verwenden, unterstützen nicht die neuesten Azure Storage Features, z. B. Zugriffsstufen für Block-Blobs, Lebenszyklusverwaltungsrichtlinien und Unveränderlichkeitsrichtlinien. GPv2-Speicherkonten bieten dieselben Funktionen sowie zusätzliche Funktionen zu wettbewerbsfähigen oder niedrigeren Preisen. Microsoft empfiehlt, alle GPv1- und BlobStorage-Konten auf GPv2 zu aktualisieren.

Identifizieren von Legacyspeicherkonten

Verwenden Sie die folgende ARG-Abfrage, um Speicherkonten zu identifizieren, die weiterhin GPv1- oder BlobStorage-Art verwenden.

resources
| where type =~ 'Microsoft.Storage/StorageAccounts'
    and kind !='StorageV2'
    and kind !='FileStorage'
| extend
    StorageAccountName = name,
    SAKind = kind,
    AccessTier = tostring(properties.accessTier),
    SKUName = sku.name,
    SKUTier = sku.tier,
    Location = location
| order by id asc
| project
    id,
    StorageAccountName,
    SKUName,
    SKUTier,
    SAKind,
    AccessTier,
    resourceGroup,
    Location,
    subscriptionId

Feedback senden

Lassen Sie uns mit einer kurzen Bewertung wissen, wie wir abschneiden. Wir verwenden diese Rezensionen, um FinOps-Tools und -Ressourcen zu verbessern und zu erweitern.

Wenn Sie nach etwas Spezifischem suchen, wählen Sie eine vorhandene Idee aus, oder erstellen Sie eine neue Idee. Teilen Sie Ideen mit anderen, um mehr Stimmen zu erhalten. Wir konzentrieren uns auf Ideen mit den meisten Stimmen.

Zugehöriger Inhalt

Verwandte Ressourcen:

• FinOps Framework

Verwandte Lösungen:

• FinOps-Toolkit Power BI-Berichte
• FinOps-Hubs
• FinOps-Arbeitsmappen
• Optimierungsmodul