X++-kørselsfunktioner for container

Note

Community-interessegrupper er nu flyttet fra Yammer til Microsoft Viva Engage. Hvis du vil deltage i et Viva Engage community og deltage i de seneste diskussioner, skal du udfylde formularen Anmodning om adgang til Finance and Operations Viva Engage Community og vælge det community, du vil deltage i.

I denne artikel beskrives kørselsfunktionerne for objektbeholderen.

Disse funktioner manipulerer indholdet af objektbeholdere.

conDel

Fjerner det angivne antal elementer fra en objektbeholder.

Syntaks

container conDel(container container, int start, int number)

Parametre

Parameter Beskrivende tekst
objektbeholder Den objektbeholder, der skal fjernes elementer fra.
begynde Den énbaserede placering, hvor elementer skal fjernes.
nummer Antallet af elementer, der skal slettes.

Returværdi

En ny objektbeholder, der ikke indeholder de fjernede elementer.

Eksempel:

static void conDelExample(Args _args)
{
    container c = ["Hello world", 1, 3.14];
    
    // Deletes the first two items from the container.
    c = conDel(c, 1, 2);
}

conFind

Finder den første forekomst af et element i en objektbeholder.

Syntaks

int conFind(container container, anytype element)

Parametre

Parameter Beskrivende tekst
objektbeholder Den objektbeholder, der skal søges i.
element Det element, der skal søges efter.

Returværdi

0 , hvis elementet ikke blev fundet. Ellers er elementets sekvensnummer.

Eksempel:

static void conFindExample(Args _args)
{
    container c = ["item1", "item2", "item3"];
    int i = conFind(c, "item2");
    int j = conFind(c, "item4");

    print "Position of 'item2' in container is " + int2Str(i);
    print "Position of 'item4' in container is " + int2Str(j);
}

conIns

Indsætter et eller flere elementer i en objektbeholder.

Syntaks

container conIns(container container, int start, anytype element, ... )

Parametre

Parameter Beskrivende tekst
objektbeholder Den objektbeholder, der skal indsættes elementer i.
begynde Den placering, elementer skal indsættes på.
element Et eller flere elementer, der skal indsættes adskilt af kommaer.

Returværdi

En ny objektbeholder, der indeholder de indsatte elementer.

Kommentarer

Det første element i objektbeholderen er angivet af tallet 1. Hvis du vil indsætte efter n-elementet, skal startparameteren være n+1. Du kan også bruge operatoren += til at føje værdier af en hvilken som helst type til en objektbeholder. Hvis du f.eks. vil oprette en objektbeholder, der indeholder de kvadrerede værdier for de første 10 løkke-gentagelser, skal du bruge følgende kode.

int i;
container c;

for (i = 1; i < = 10; i++)
{
    // Append the square of the index to the container
    c += i*i;
}

Eksempel:

static void conInsExample(Args _arg)
{
    container c;
    int i;

    c = conIns(c,1,"item1");
    c = conIns(c,2,"item2");

    for (i = 1 ; i <= conLen(c) ; i++)
    {
        // Prints the content of a container.
        print conPeek(c, i);
    }
}

conLen

Henter antallet af elementer i en objektbeholder.

Syntaks

int conLen(container container)

Parametre

Parameter Beskrivende tekst
objektbeholder Den objektbeholder, hvor antallet af elementer skal tælles i.

Returværdi

Antallet af elementer i objektbeholderen. ConNull-objektbeholderen har ingen elementer.

Eksempel:

static void conLenExample(Args _arg)
{
    container c = conins(["item1", "item2"], 1);

    for (int i = 1 ; i <= conLen(c) ; i++)
    {
        print conPeek(c, i);
    }
}

conNull

Henter en tom objektbeholder.

container conNull()

Returværdi

En tom objektbeholder.

Eksempel:

static void conNullExample(Args _arg)
{
    container c = ["item1", "item2", "item3"];

    print "The size of container is " + int2str(conLen(c));

    // Set the container to null.
    c = conNull();
    print "Size of container after conNull() is " + int2Str(conLen(c));
}

conPeek

Henter et bestemt element fra en objektbeholder og konverterer det til en anden datatype, hvis konvertering er påkrævet.

Syntaks

anytype conPeek(container container, int number)

Parametre

Parameter Beskrivende tekst
objektbeholder Den objektbeholder, der skal returneres et element fra.
nummer Placeringen af det element, der skal returneres. Angiv 1 for at hente det første element. Et ugyldigt positionsnummer, f.eks. -3, 0, eller et tal, der er højere end objektbeholderens længde, kan medføre uforudsigelige fejl.

Returværdi

Elementet i objektbeholderen på den placering, som talparameteren angiver. Funktionen conPeek konverterer automatisk det smugkigte element til den forventede returtype. Strenge kan automatisk konverteres til heltal og reelle tal, og heltal og reelle tal kan konverteres til strenge.

Eksempel:

static void main(Args _args)
{
    container cnI, cnJ;
    int i, j;
    anytype aty;
    
    info("container cnI ...");
    cnI = ["itemBlue", "itemYellow"];

    for (i=1; i <= conLen(cnI); i++)
    {
        aty = conPeek(cnI, i);
        info(int2str(i) + " :  " + aty);
    }

    info("container cnJ ...");
    cnJ = conIns(cnI, 2, "ItemInserted");

    for (j=1; j <= conLen(cnJ); j++)
    {
        aty = conPeek(cnJ, j);
        info(int2str(j) + " :  " + aty);
    }
}
/***  Output pasted from InfoLog ...
Message (10:20:03 am)
container cnI ...
1 :  itemBlue
2 :  itemYellow
container cnJ ...
1 :  itemBlue
2 :  ItemInserted
3 :  itemYellow
***/

conPoke

Ændrer en objektbeholder ved at erstatte et eller flere af de eksisterende elementer.

Syntaks

container conPoke(container container, int start, anytype element, ...)

Parametre

Parameter Beskrivende tekst
objektbeholder Den objektbeholder, der skal redigeres.
begynde Placeringen af det første element, der skal erstattes.
element Et eller flere elementer, der skal erstattes adskilt af kommaer.

Returværdi

En ny objektbeholder, der indeholder de nye elementer.

Kommentarer

Det første element i objektbeholderen er angivet af tallet 1.

Eksempel:

static void conPokeExample(Args _arg)
{
    container c1 = ["item1", "item2", "item3"];
    container c2;
    int i;

    void conPrint(container c)
    {
        for (i = 1 ; i <= conLen(c) ; i++)
        {
            print conPeek(c, i);
        }
    }

    conPrint(c1);
    c2 = conPoke(c1, 2, "PokedItem");
    print "";
    conPrint(c2);
}
  • Last updated on